The Money Is Calling And I Am Cutting To Get It: Adds Fully Player Buildable Shipbreaking For Fun, Profit, And Liveleak Tier Industrial Accidents

code/__DEFINES/~doppler_defines/shipbreaking.dm

@@ -0,0 +1,16 @@
+/// Ship contains electrical hazards
+#define SALVAGE_HAZARD_ELECTRICAL "Electrical Hazards"
+/// Ship contains explosive fuels
+#define SALVAGE_HAZARD_FUEL "Explosive Fuels"
+/// Ship contains radioactive things
+#define SALVAGE_HAZARD_RADIATION "Above-Background Radioactivity"
+/// Ship contains a shipmind or equivalent
+#define SALVAGE_HAZARD_SHIPMIND "Potentially Active Shipmind"
+/// Ship contains coolant canisters
+#define SALVAGE_HAZARD_COOLANT "Superketone Coolant"
+/// Ship contains a reactor
+#define SALVAGE_HAZARD_REACTOR "Active Bloom Reactor"
+/// Ship has nonspecific cargo that might be dangerous
+#define SALVAGE_HAZARD_CARGO "Potentially Volatile Cargo"
+/// Ship has munitions on board
+#define SALVAGE_HAZARD_WEAPONS "Uncleared Weaponry"

code/__DEFINES/~doppler_defines/traits/declarations.dm

@@ -22,3 +22,9 @@
 // makes it so held items float by their head
 #define TRAIT_FLOATING_HELD "held_items_float"
 
+/// Do non-items still get recycled for their custom materials
+#define TRAIT_RECYCLE_LIKE_ITEM "recycle_like_an_item"
+/// Do we get recolored based off of a salvage ship datum's primary colour
+#define TRAIT_SHIP_PRIMARY_COLOUR "salvage_ship_primary_colour"
+/// Do we get recolored based off of a salvage ship datum's secondary colour
+#define TRAIT_SHIP_SECONDARY_COLOUR "salvage_ship_secondary_colour"

code/_globalvars/traits/_traits.dm

@@ -37,6 +37,8 @@ GLOBAL_LIST_INIT(traits_by_type, list(
 		"TRAIT_UNHITTABLE_BY_LASERS" = TRAIT_UNHITTABLE_BY_LASERS,
 		"TRAIT_UNLINKABLE_FISHING_SPOT" = TRAIT_UNLINKABLE_FISHING_SPOT,
 		"TRAIT_TETHER_ATTACHED" = TRAIT_TETHER_ATTACHED,
+		"TRAIT_SHIP_PRIMARY_COLOUR" = TRAIT_SHIP_PRIMARY_COLOUR, // DOPPLER EDIT ADDITION
+		"TRAIT_SHIP_SECONDARY_COLOUR" = TRAIT_SHIP_SECONDARY_COLOUR, // DOPPLER EDIT ADDITION
 	),
 	/atom/movable = list(
 		"TRAIT_ACTIVE_STORAGE" = TRAIT_ACTIVE_STORAGE,
@@ -660,7 +662,7 @@ GLOBAL_LIST_INIT(traits_by_type, list(
 		"TRAIT_CARP_GOODTOX" = TRAIT_CARP_GOODTOX, // DOPPLER EDIT ADDITION
 		"TRAIT_CHAMELEON_SKIN" = TRAIT_CHAMELEON_SKIN, // DOPPLER EDIT ADDITION
 		"TRAIT_FLOATING_HELD" = TRAIT_FLOATING_HELD, // DOPPLER EDIT ADDITION
-
+		"TRAIT_RECYCLE_LIKE_ITEM" = TRAIT_RECYCLE_LIKE_ITEM, // DOPPLER EDIT ADDITION
 	),
 	/mob/dead/observer = list(
 		"TRAIT_NO_OBSERVE" = TRAIT_NO_OBSERVE,

code/_globalvars/traits/admin_tooling.dm

@@ -8,6 +8,8 @@ GLOBAL_LIST_INIT(admin_visible_traits, list(
 		"TRAIT_KEEP_TOGETHER" = TRAIT_KEEP_TOGETHER,
 		"TRAIT_UNHITTABLE_BY_PROJECTILES" = TRAIT_UNHITTABLE_BY_PROJECTILES,
 		"TRAIT_UNHITTABLE_BY_LASERS" = TRAIT_UNHITTABLE_BY_LASERS,
+		"TRAIT_SHIP_PRIMARY_COLOUR" = TRAIT_SHIP_PRIMARY_COLOUR, // DOPPLER EDIT ADDITION
+		"TRAIT_SHIP_SECONDARY_COLOUR" = TRAIT_SHIP_SECONDARY_COLOUR, // DOPPLER EDIT ADDITION
 	),
 	/atom/movable = list(
 		"TRAIT_ASHSTORM_IMMUNE" = TRAIT_ASHSTORM_IMMUNE,
@@ -31,6 +33,7 @@ GLOBAL_LIST_INIT(admin_visible_traits, list(
 		"TRAIT_CONTRABAND" = TRAIT_CONTRABAND,
 		"TRAIT_DUCT_TAPE_UNREPAIRABLE" = TRAIT_DUCT_TAPE_UNREPAIRABLE,
 		"TRAIT_SPEED_POTIONED" = TRAIT_SPEED_POTIONED,
+		"TRAIT_RECYCLE_LIKE_ITEM" = TRAIT_RECYCLE_LIKE_ITEM, // DOPPLER EDIT ADDITION
 	),
 	/mob = list(
 		"TRAIT_ABDUCTOR_HUD" = TRAIT_ABDUCTOR_HUD,

code/game/machinery/recycler.dm

@@ -225,7 +225,7 @@
 			break
 		var/full_power_usage = TRUE
 		var/obj/nom_obj = nom[i]
-		if (isitem(nom_obj))
+		if((isitem(nom_obj)) || (HAS_TRAIT(nom_obj, TRAIT_RECYCLE_LIKE_ITEM))) // DOPPLER EDIT CHANGE - Lets non-items get their custom materials recycled - ORIGINAL: if (isitem(nom_obj))
 			// Whether or not items consume full power depends on if they produced a material when recycled.
 			full_power_usage = recycle_item(nom_obj)
 		else

code/modules/asset_cache/assets/sheetmaterials.dm

@@ -3,4 +3,5 @@
 
 /datum/asset/spritesheet_batched/sheetmaterials/create_spritesheets()
 	insert_all_icons("", 'icons/obj/stack_objects.dmi')
+	insert_all_icons("", 'modular_doppler/shipbreaking/icons/stacks.dmi') // DOPPLER EDIT ADDITION - SHIPBREAKING MATS DONT RENDER RIGHT
 

modular_doppler/colony_fabricator/code/power/rtg.dm

@@ -21,6 +21,11 @@
 	AddElement(/datum/element/radioactive, threshold = RAD_VERY_LIGHT_INSULATION, minimum_exposure_time = NEBULA_RADIATION_MINIMUM_EXPOSURE_TIME)
 	AddElement(/datum/element/manufacturer_examine, COMPANY_FRONTIER)
 
+/obj/machinery/power/rtg/portable/wrench_act(mob/living/user, obj/item/tool)
+	. = ..()
+	default_unfasten_wrench(user, tool, time = 2 SECONDS)
+	return ITEM_INTERACT_SUCCESS
+
 /obj/machinery/power/rtg/portable/RefreshParts()
 	. = ..()
 	power_gen = initial(power_gen)

modular_doppler/epic_loot/code/loot_items/components.dm

@@ -1,5 +1,5 @@
 /datum/export/epic_loot_components
-	cost = PAYCHECK_COMMAND
+	cost = 50
 	unit_name = "low value salvage"
 	export_types = list(
 		/obj/item/epic_loot/grenade_fuze,
@@ -10,7 +10,7 @@
 	)
 
 /datum/export/epic_loot_components_super
-	cost = PAYCHECK_COMMAND * 2
+	cost = 75
 	unit_name = "salvage"
 	export_types = list(
 		/obj/item/epic_loot/water_filter,
@@ -20,7 +20,7 @@
 	)
 
 /datum/export/epic_loot_components_super_super
-	cost = PAYCHECK_COMMAND * 3
+	cost = 125
 	unit_name = "high value salvage"
 	export_types = list(
 		/obj/item/epic_loot/thermal_camera,

modular_doppler/epic_loot/code/loot_items/electronics.dm

@@ -1,5 +1,5 @@
 /datum/export/epic_loot_electronics
-	cost = PAYCHECK_COMMAND
+	cost = 50
 	unit_name = "electronic salvage"
 	export_types = list(
 		/obj/item/epic_loot/device_fan,
@@ -10,7 +10,7 @@
 	)
 
 /datum/export/epic_loot_electronics_super
-	cost = PAYCHECK_COMMAND * 2
+	cost = 75
 	unit_name = "high value electronic salvage"
 	export_types = list(
 		/obj/item/epic_loot/display,

modular_doppler/epic_loot/code/loot_items/medical.dm

@@ -1,5 +1,5 @@
 /datum/export/epic_loot_super_med_tools
-	cost = PAYCHECK_COMMAND * 5
+	cost = 250
 	unit_name = "high value medical salvage"
 	export_types = list(
 		/obj/item/epic_loot/vein_finder,

modular_doppler/epic_loot/code/loot_items/valuables.dm

@@ -1,5 +1,5 @@
 /datum/export/epic_loot_valuables
-	cost = PAYCHECK_COMMAND * 3
+	cost = 150
 	unit_name = "recovered valuables"
 	export_types = list(
 		/obj/item/epic_loot/press_pass,
@@ -10,7 +10,7 @@
 	)
 
 /datum/export/epic_loot_valuables_super
-	cost = PAYCHECK_COMMAND * 4
+	cost = 200
 	unit_name = "recovered high valuables"
 	export_types = list(
 		/obj/item/epic_loot/ssd,

modular_doppler/shipbreaking/code/docking_clamp.dm

@@ -0,0 +1,151 @@
+/obj/effect/temp_visual/telegraphing/long_duration
+	duration = 15 SECONDS
+
+// Circuit and RND
+
+/obj/item/circuitboard/machine/docking_clamp
+	name = "Salvage Clamp"
+	greyscale_colors = CIRCUIT_COLOR_ENGINEERING
+	build_path = /obj/machinery/docking_clamp
+
+/datum/design/board/salvage_docking_clamp
+	name = "Salvage Clamp"
+	desc = "A large clamp for holding shuttles in place without using their own power."
+	id = "salvage_docking_clamp"
+	build_path = /obj/item/circuitboard/machine/docking_clamp
+	category = list(
+		RND_CATEGORY_COMPUTER + RND_SUBCATEGORY_COMPUTER_ENGINEERING
+	)
+	departmental_flags = DEPARTMENT_BITFLAG_ENGINEERING
+
+/datum/techweb_node/mining/New()
+	design_ids += list(
+		"salvage_docking_clamp",
+	)
+	return ..()
+
+// Everything else
+
+/obj/machinery/docking_clamp
+	name = "salvage clamp"
+	desc = "A large clamp for holding shuttles in place without using their own power."
+	icon = 'icons/obj/machines/floor.dmi'
+	icon_state = "mass_driver"
+	use_power = NO_POWER_USE
+	circuit = /obj/item/circuitboard/machine/docking_clamp
+	/// The docking port we use to connect ships with
+	var/obj/docking_port/stationary/salvage_dock/docking_port
+	/// The computer the clamp is linked to
+	var/obj/machinery/computer/salvage_bay_controller/controller
+
+/obj/machinery/docking_clamp/Initialize(mapload)
+	. = ..()
+	AddComponent(/datum/component/simple_rotation)
+
+/obj/machinery/docking_clamp/Destroy(force)
+	if(controller)
+		controller.delink_clamp()
+	if(docking_port)
+		QDEL_NULL(docking_port)
+	return ..()
+
+/obj/machinery/docking_clamp/examine(mob/user)
+	. = ..()
+	if(!controller)
+		. += span_notice("Use a [EXAMINE_HINT("multitool")] to connect this to a [EXAMINE_HINT("salvage bay control console")] before use.")
+	if(!docking_port)
+		. += span_notice("Interact with the clamp to set it up for docking, otherwise it will not function.")
+		. += span_notice("The clamp requires a large space in front of it, indicated by holograms on setup.")
+		. += span_notice("This space is [EXAMINE_HINT("[floor(/obj/docking_port/stationary/salvage_dock::width / 2)]")] tiles to either side of the clamp, and [EXAMINE_HINT("[/obj/docking_port/stationary/salvage_dock::height]")] tiles straight out.")
+
+/obj/machinery/docking_clamp/multitool_act(mob/living/user, obj/item/multitool/the_tool)
+	if(!panel_open)
+		balloon_alert(user, "panel closed!")
+		return ITEM_INTERACT_BLOCKING
+	the_tool.set_buffer(src)
+	balloon_alert(user, "saved to multitool buffer")
+	return ITEM_INTERACT_SUCCESS
+
+/obj/machinery/docking_clamp/wrench_act(mob/living/user, obj/item/tool)
+	if(!panel_open)
+		balloon_alert(user, "panel closed!")
+		return ITEM_INTERACT_BLOCKING
+	if(!default_unfasten_wrench(user, tool, 4 SECONDS))
+		return ITEM_INTERACT_BLOCKING
+	if(!anchored)
+		QDEL_NULL(docking_port)
+	return ITEM_INTERACT_SUCCESS
+
+/obj/machinery/docking_clamp/screwdriver_act(mob/user, obj/item/tool)
+	if(!default_deconstruction_screwdriver(user, icon_state, icon_state, tool))
+		return ITEM_INTERACT_BLOCKING
+	update_appearance()
+	return ITEM_INTERACT_SUCCESS
+
+/obj/machinery/docking_clamp/crowbar_act(mob/user, obj/item/tool)
+	if(!default_deconstruction_crowbar(tool))
+		return ITEM_INTERACT_BLOCKING
+	return ITEM_INTERACT_SUCCESS
+
+/obj/machinery/docking_clamp/interact(mob/user)
+	if(!can_interact(user))
+		return
+	if(!anchored)
+		balloon_alert(user, "not secured!")
+		return ..()
+	if(docking_port)
+		balloon_alert(user, "unsetting...")
+		if(!do_after(user, 3 SECONDS, src))
+			return ..()
+		QDEL_NULL(docking_port)
+		return ..()
+	balloon_alert(user, "setting clamp")
+	if(!do_after(user, 2 SECONDS, src))
+		return ..()
+	var/turf/dock_location = get_step(src, dir)
+	var/obj/docking_port/stationary/salvage_dock/temp_docking_port = new(dock_location, dir)
+	var/list/docking_turfs = temp_docking_port.return_turfs()
+	var/list/dock_bounds = temp_docking_port.return_coords()
+	var/list/overlappers = SSshuttle.get_dock_overlap(dock_bounds[1], dock_bounds[2], dock_bounds[3], dock_bounds[4], z)
+	if(length(overlappers)) // Overlappers list contains ourself as well
+		for(var/dock as anything in overlappers)
+			if(dock == temp_docking_port)
+				continue
+			balloon_alert(user, "intersecting nearby dock")
+			temp_docking_port.Destroy(TRUE)
+			return ..()
+	for(var/turf/checked_turf as anything in docking_turfs)
+		if(checked_turf.x <= 10 || checked_turf.y <= 10 || checked_turf.x >= world.maxx - 10 || checked_turf.y >= world.maxy - 10)
+			balloon_alert(user, "cannot place here")
+			new /obj/effect/temp_visual/telegraphing/long_duration(checked_turf)
+			temp_docking_port.Destroy(TRUE)
+			return ..()
+		var/area/turf_area = get_area(checked_turf)
+		if(!is_space_or_openspace(checked_turf) || checked_turf.is_blocked_turf(TRUE) || !is_area_nearby_station(turf_area))
+			balloon_alert(user, "dock not clear")
+			new /obj/effect/temp_visual/telegraphing/long_duration(checked_turf)
+			temp_docking_port.Destroy(TRUE)
+			return ..()
+		new /obj/effect/temp_visual/medical_holosign(checked_turf)
+	docking_port = temp_docking_port
+	return ..()
+
+/// Scans the docking port area for if living mobs are present inside, TRUE means a mob is in the way (or we have no port?)
+/obj/machinery/docking_clamp/proc/check_for_clear_bay()
+	if(!docking_port)
+		return TRUE // what ?? No
+	var/list/docking_turfs = docking_port.return_turfs()
+	for(var/turf/checked_turf as anything in docking_turfs)
+		for(var/mob/living/living_mob in checked_turf.contents)
+			return TRUE
+	return FALSE
+
+/obj/docking_port/stationary/salvage_dock
+	name = "Salvage Dock"
+	width = 31
+	height = 19
+	dwidth = 15
+
+/obj/docking_port/stationary/salvage_dock/Initialize(mapload, dock_direction)
+	setDir(dock_direction)
+	. = ..()