Build with nix

.gitignore

@@ -10,4 +10,3 @@ tests/examples/cur
 tests/examples/diff
 web/elm-stuff
 static/web.js
-stack.yaml.lock

Makefile

@@ -1,7 +1,6 @@
 .PHONY: format test compare ghcid
 
-LOCALINSTALL := $(shell stack $(STACKARGS) path | grep ^local-install-root: | awk '{print $$2}')/bin
-DRAW = $(LOCALINSTALL)/drawpuzzle
+DRAW ?= $(shell cabal list-bin drawpuzzle)
 
 ghcid:
 	ghcid

flake.nix

@@ -0,0 +1,80 @@
+{
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs";
+    flake-utils.url = "github:numtide/flake-utils";
+  };
+
+  outputs = {
+    self,
+    nixpkgs,
+    flake-utils,
+  }:
+    flake-utils.lib.eachDefaultSystem (system: let
+      pkgs = nixpkgs.legacyPackages.${system};
+      t = pkgs.lib.trivial;
+      hl = pkgs.haskell.lib;
+
+      name = "puzzld";
+
+      project = devTools: let
+        addBuildTools = (t.flip hl.addBuildTools) devTools;
+      in
+        pkgs.haskellPackages.developPackage {
+          root =
+            pkgs.lib.sourceFilesBySuffices ./.
+            [".cabal" ".hs" "LICENSE" ".svg" ".pzg" ".pzl" ".png" ".sh" "Makefile"];
+          name = name;
+          returnShellEnv = !(devTools == []);
+          source-overrides = {"SVGFonts" = "1.7.0.1";};
+          modifier = (t.flip t.pipe) [
+            addBuildTools
+            ((t.flip hl.addBuildTools) [pkgs.imagemagick])
+            hl.dontHaddock
+            hl.enableStaticLibraries
+            hl.justStaticExecutables
+            hl.disableLibraryProfiling
+            hl.disableExecutableProfiling
+            ((t.flip hl.overrideCabal) (drv: {
+              postCheck = ''
+                patchShebangs tests/examples/gallery.sh
+                make compare DRAW=$(pwd)/dist/build/drawpuzzle/drawpuzzle
+              '';
+            }))
+          ];
+        };
+    in {
+      packages = rec {
+        puzzle-draw = project [];
+        puzzle-draw-web = pkgs.callPackage ./nix/web.nix {};
+        puzzle-draw-serve = import ./nix/serve.nix {
+          inherit pkgs system;
+          inherit puzzle-draw puzzle-draw-web;
+          src = self;
+        };
+      };
+      defaultPackage = self.packages.${system}.puzzle-draw;
+
+      devShell = project [
+        pkgs.haskellPackages.cabal-fmt
+        pkgs.haskellPackages.cabal-install
+      ];
+    })
+    // rec {
+      nixosModule = import ./nix/module.nix;
+      nixosConfigurations.test = nixpkgs.lib.nixosSystem rec {
+        system = "x86_64-linux";
+        modules = [
+          ({
+            config,
+            pkgs,
+            ...
+          }: {
+            boot.isContainer = true;
+            services.puzzle-draw.enable = true;
+            services.puzzle-draw.package = self.packages.${system}.puzzle-draw-serve;
+          })
+          nixosModule
+        ];
+      };
+    };
+}

nix/module.nix

@@ -0,0 +1,67 @@
+{
+  config,
+  lib,
+  pkgs,
+  modulesPath,
+  ...
+}:
+with lib; let
+  cfg = config.services.puzzle-draw;
+in {
+  options.services.puzzle-draw = {
+    enable = mkEnableOption "puzzle-draw server";
+
+    package = mkOption {
+      default = pkgs.puzzle-draw-serve;
+      defaultText = "pkgs.puzzle-draw-serve";
+      type = types.package;
+      description = ''
+        puzzle-draw-serve package to use.
+      '';
+    };
+
+    hostName = mkOption {
+      type = types.nullOr types.str;
+      default = null;
+      description = "Hostname to serve puzzle-draw virtual host on (null to disable)";
+    };
+
+    nginx = mkOption {
+      type =
+        types.submodule
+        (import "${modulesPath}/services/web-servers/nginx/vhost-options.nix" {
+          inherit config lib;
+        });
+      default = {};
+      description = "Extra configuration for the nginx virtual host of puzzle-draw.";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    systemd.services.puzzle-draw = {
+      description = "Run puzzle-draw server";
+      wantedBy = ["multi-user.target"];
+      after = ["networking.target"];
+      serviceConfig = {
+        WorkingDirectory = "${cfg.package}";
+        ExecStart = "${cfg.package}/bin/servepuzzle -b 127.0.0.1 -p 8765";
+        Restart = "always";
+      };
+    };
+    services.nginx = {
+      upstreams.puzzle-draw-backend.servers."localhost:8765" = {};
+      virtualHosts = mkIf (cfg.hostName != null) {
+        "${cfg.hostName}" = mkMerge [
+          cfg.nginx
+          {
+            locations = {
+              "/" = {
+                proxyPass = "http://puzzle-draw-backend/";
+              };
+            };
+          }
+        ];
+      };
+    };
+  };
+}