Switch to gradle and enable local debugging

.gitignore

@@ -18,7 +18,6 @@ out/
 *.ctxt
 
 # Package Files #
-*.jar
 *.war
 *.nar
 *.ear
@@ -101,6 +100,7 @@ pom.xml.tag
 pom.xml.releaseBackup
 pom.xml.versionsBackup
 pom.xml.next
+.gradle/
 
 release.properties
 dependency-reduced-pom.xml
@@ -111,3 +111,4 @@ buildNumber.properties
 
 # Common working directory
 run/
+build/

build.gradle

@@ -0,0 +1,67 @@
+import xyz.jpenilla.runpaper.task.RunServer
+
+plugins {
+    id 'java'
+    id("xyz.jpenilla.run-paper") version "3.0.2"
+}
+
+group = 'me.usainsrht'
+version = '1.7'
+description = 'Simple stair sitting plugin.'
+
+java {
+    sourceCompatibility = JavaVersion.VERSION_11
+    targetCompatibility = JavaVersion.VERSION_11
+}
+
+repositories {
+    maven { url = 'https://hub.spigotmc.org/nexus/content/groups/public/' }
+    mavenCentral()
+}
+
+dependencies {
+    compileOnly 'org.spigotmc:spigot-api:1.13-R0.1-SNAPSHOT'
+}
+
+tasks.withType(JavaCompile).configureEach {
+    options.encoding = 'UTF-8'
+}
+
+processResources {
+    filteringCharset = 'UTF-8'
+    filesMatching('plugin.yml') {
+        expand(project: [version: project.version])
+    }
+}
+
+jar {
+    archiveBaseName = 'sit'
+}
+
+// https://papermc.io/downloads/all
+def supportedVersions = ["1.21.11",
+                         "1.20.6",
+                         "1.19.4",
+                         "1.18.2",
+                         "1.17.1",
+                         "1.16.5",
+                         "1.15.2",
+                         "1.14.4",
+                         "1.13", "1.13.2",
+                         ]
+
+supportedVersions.forEach { version ->
+    tasks.register("runServer-$version", RunServer) {
+        dependsOn("build")
+        minecraftVersion(version)
+        if (version.startsWith("1.13") || version.startsWith("1.14")) {
+            javaLauncher.set(javaToolchains.launcherFor {
+                languageVersion.set(JavaLanguageVersion.of(11))
+            })
+        }
+        runDirectory.set(file("run/$version"))
+        jvmArgs("-DPaper.IgnoreJavaVersion=true", "-Dcom.mojang.eula.agree=true")
+        group = "run paper"
+        pluginJars = files("$rootDir/build/libs/sit-${project.version}.jar")
+    }
+}

gradle/wrapper/gradle-wrapper.properties

@@ -0,0 +1,7 @@
+distributionBase=GRADLE_USER_HOME
+distributionPath=wrapper/dists
+distributionUrl=https\://services.gradle.org/distributions/gradle-9.0.0-bin.zip
+networkTimeout=10000
+validateDistributionUrl=true
+zipStoreBase=GRADLE_USER_HOME
+zipStorePath=wrapper/dists