languages/fish: init

configuration.nix

@@ -92,6 +92,7 @@ isMaximal: {
       fsharp.enable = false;
       just.enable = false;
       qml.enable = false;
+      fish.enable = false;
 
       tailwind.enable = false;
       svelte.enable = false;

docs/manual/release-notes/rl-0.9.md

@@ -146,6 +146,14 @@
 
 - Added `ruff` and `ty` LSP support for Python under `programs.python`.
 
+[Poseidon](https://github.com/poseidon-rises):
+
+[fish-lsp]: https://www.fish-lsp.dev/
+[fish_indent]: https://fishshell.com/docs/current/cmds/fish_indent.html
+
+- Added Fish support via {option}`languages.fish` using [fish-lsp] and
+  [fish_indent].
+
 [Snoweuph](https://github.com/snoweuph)
 
 - Added [Selenen](https://github.com/kampfkarren/selene) for more diagnostics in

modules/plugins/languages/default.nix

@@ -12,6 +12,7 @@ in {
     ./clojure.nix
     ./css.nix
     ./elixir.nix
+    ./fish.nix
     ./fsharp.nix
     ./gleam.nix
     ./go.nix

modules/plugins/languages/fish.nix

@@ -0,0 +1,107 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}:
+let
+  inherit (builtins) attrNames;
+  inherit (lib.meta) getExe;
+  inherit (lib.options) mkEnableOption mkOption;
+  inherit (lib.modules) mkIf mkMerge;
+  inherit (lib.types) enum package listOf;
+  inherit (lib.nvim.types) mkGrammarOption;
+  inherit (lib.nvim.attrsets) mapListToAttrs;
+
+  cfg = config.vim.languages.fish;
+
+  defaultServers = [ "fish-lsp" ];
+  servers = {
+    fish-lsp = {
+      cmd = [
+        (getExe pkgs.fish-lsp)
+        "start"
+      ];
+      filetypes = [ "fish" ];
+      root_markers = [
+        "config.fish"
+        ".git"
+      ];
+    };
+  };
+
+  defaultFormat = [ "fish_indent" ];
+  formats = {
+    fish_indent = {
+      package = pkgs.fish;
+      config.command = "${cfg.format.package}/bin/fish_indent";
+    };
+  };
+in
+{
+  options.vim.languages.fish = {
+    enable = mkEnableOption "Fish language support";
+    treesitter = {
+      enable = mkEnableOption "Fish treesitter support" // {
+        default = config.vim.languages.enableTreesitter;
+      };
+      package = mkGrammarOption pkgs "fish";
+    };
+
+    lsp = {
+      enable = mkEnableOption "Fish LSP support" // {
+        default = config.vim.lsp.enable;
+      };
+      servers = mkOption {
+        type = listOf (enum (attrNames servers));
+        default = defaultServers;
+        description = "Fish LSP server to use";
+      };
+    };
+
+    format = {
+      enable = mkEnableOption "Fish formatting" // {
+        default = config.vim.languages.enableFormat;
+      };
+
+      type = mkOption {
+        type = listOf (enum (attrNames formats));
+        default = defaultFormat;
+        description = "Fish formatter to use";
+      };
+
+      package = mkOption {
+        type = package;
+        default = formats.${cfg.format.type}.package;
+        description = "Fish formatter package";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable (mkMerge [
+    (mkIf cfg.treesitter.enable {
+      vim.treesitter = {
+        enable = true;
+        grammars = [ cfg.treesitter.package ];
+      };
+    })
+
+    (mkIf cfg.lsp.enable {
+      vim.lsp.servers = mapListToAttrs (n: {
+        name = n;
+        value = servers.${n};
+      }) cfg.lsp.servers;
+    })
+
+    (mkIf (cfg.format.enable && !cfg.lsp.enable) {
+      vim.formatter.conform-nvim = {
+        enable = true;
+        setupOpts.formatters_by_ft.fish = cfg.format.type;
+        setupOpts.formatters = mapListToAttrs (name: {
+          inherit name;
+          value = formats.${name};
+        }) cfg.format.type;
+      };
+    })
+  ]);
+}