New geyser extension!

.run/GeyserRun.run.xml

@@ -0,0 +1,9 @@
+<component name="ProjectRunConfigurationManager">
+  <configuration default="false" name="GeyserRun" type="Application" factoryName="Application">
+    <option name="MAIN_CLASS_NAME" value="org.redlance.dima_dencep.mods.emotecraft.geyser.GeyserBootstrap" />
+    <module name="emotecraft.geyser.main" />
+    <option name="VM_PARAMETERS" value="-Djava.awt.headless=true -XX:+AllowEnhancedClassRedefinition" />
+    <option name="WORKING_DIRECTORY" value="$PROJECT_DIR$/geyser/run" />
+    <method v="2" />
+  </configuration>
+</component>

build.gradle.kts

@@ -3,6 +3,7 @@ import org.redlance.dima_dencep.gradle.publish2discord.utils.Emoji
 import me.modmuss50.mpp.ReleaseType
 
 plugins {
+    id("xyz.wagyourtail.jvmdowngrader") version("1.3.3") apply false
     id("dev.architectury.loom") version "1.13.467" apply false
     id("architectury-plugin") version "3.4.162" apply true
     id("com.gradleup.shadow") version "9.3.0" apply false
@@ -36,6 +37,9 @@ allprojects {
             }
         }
         maven("https://maven.neoforged.net/releases")
+        maven("https://repo.opencollab.dev/main/") {
+            name = "Geyser"
+        }
         mavenLocal()
     }
 
@@ -105,6 +109,7 @@ val ds = publishDiscord {
     links {
         from(":minecraft:neoforge", "modrinth")
         from(":minecraft:fabric", "modrinth")
+        from(":geyser", "modrinth")
 
         val paper = project(":paper")
         from(paper, "modrinth")

emotesAPI/src/main/java/io/github/kosmx/emotes/common/tools/MathHelper.java

@@ -1,5 +1,7 @@
 package io.github.kosmx.emotes.common.tools;
 
+import io.netty.buffer.ByteBuf;
+
 import java.io.IOException;
 import java.io.InputStream;
 import java.nio.ByteBuffer;
@@ -23,4 +25,10 @@ public static byte[] safeGetBytesFromBuffer(ByteBuffer byteBuffer) {
         }
         else return byteBuffer.array();
     }
+
+    public static byte[] readBytes(ByteBuf buf) {
+        byte[] bytes = new byte[buf.readableBytes()];
+        buf.readBytes(bytes);
+        return bytes;
+    }
 }

geyser/build.gradle.kts

@@ -0,0 +1,117 @@
+import me.modmuss50.mpp.ReleaseType
+
+plugins {
+    java
+    `maven-publish`
+    id("com.gradleup.shadow")
+    id("xyz.wagyourtail.jvmdowngrader")
+    id("me.modmuss50.mod-publish-plugin")
+}
+
+base.archivesName = "${archives_base_name}-${name}-for-MC${minecraft_version}"
+version = mod_version
+
+val compileApi = configurations.register("compileApi").get()
+configurations.api.configure { extendsFrom(compileApi) }
+
+dependencies {
+    compileOnly("org.geysermc.geyser:core:${properties["geyser_version"] as String}")
+    implementation("org.geysermc.geyser:standalone:${properties["geyser_version"] as String}")
+
+    compileApi(project(":emotesAssets"))
+    compileApi(project(":emotesServer")) {
+        exclude(group = "org.jetbrains", module = "annotations")
+
+        exclude(module = "gson")
+        exclude(module = "slf4j-api")
+        // exclude(module = "fastutil")
+        exclude(module = "netty-buffer")
+        exclude(module = "jspecify")
+        exclude(module = "guava")
+        exclude(module = "error_prone_annotations")
+        exclude(module = "netty-buffer")
+    }
+}
+
+tasks {
+    processResources {
+        inputs.property("version", version)
+        inputs.property("description", mod_description)
+
+        filesMatching("extension.yml") {
+            expand("version" to version, "description" to mod_description)
+        }
+    }
+
+    shadowJar {
+        configurations = listOf(compileApi)
+        archiveClassifier.set("shaded")
+        mergeServiceFiles()
+
+        relocate("team.unnamed.mocha", "com.zigythebird.playeranim.lib.mochafloats")
+        relocate("javassist", "com.zigythebird.playeranim.lib.javassist")
+    }
+
+    downgradeJar {
+        dependsOn(shadowJar)
+
+        downgradeTo = JavaVersion.VERSION_17
+        inputFile = shadowJar.get().archiveFile
+        archiveClassifier.set("")
+    }
+
+    jar {
+        archiveClassifier.set("dev")
+    }
+
+    assemble {
+        dependsOn(downgradeJar)
+    }
+}
+
+java {
+    withSourcesJar()
+}
+
+publishing {
+    publications {
+        register<MavenPublication>("mavenJava") {
+            artifactId = "emotesGeyser"
+            from(components["java"])
+            withCustomPom("emotesGeyser", "Minecraft Emotecraft Geyser extension")
+        }
+    }
+
+    repositories {
+        if (shouldPublishMaven) {
+            kosmxRepo(project)
+        } else {
+            mavenLocal()
+        }
+    }
+}
+
+publishMods {
+    modLoaders.add("geyser")
+
+    file.set(tasks.downgradeJar.get().archiveFile) // Java 17
+    // additionalFiles.from(tasks.shadowJar.get().archiveFile) // Java 21
+
+    type = ReleaseType.of(releaseType)
+    changelog = changes
+    dryRun = gradle.startParameter.isDryRun
+
+    github {
+        accessToken = providers.environmentVariable("GH_TOKEN")
+        parent(rootProject.tasks.named("publishGithub"))
+    }
+
+    modrinth {
+        announcementTitle = "Modrinth (Geyser)"
+        accessToken = providers.environmentVariable("MODRINTH_TOKEN")
+        projectId = providers.gradleProperty("modrinth_id")
+        minecraftVersions.addAll(release_minecraft_versions)
+        displayName = mod_version
+        version = "${mod_version}+${removePreRc(minecraft_version)}-geyser"
+    }
+}