PGE-Project/pge.pro at master · zigurana/PGE-Project · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
include(_common/dest_dir.pri)

TEMPLATE = subdirs

DEFINES += USE_LUA_JIT

android: {
DEFINES -= USE_LUA_JIT
}

macx:{
DEFINES -= USE_LUA_JIT
}

useccache: {
#To speed-up building process http://www.ysbl.york.ac.uk/~lohkamp/speedup_compilation.html
QMAKE_CC = ccache gcc
QMAKE_CXX = ccache g++
message("CHACHE with GCC will be used")
}
#CONFIG+=release CONFIG-=debug QTPLUGIN.platforms=qxcb

SUBDIRS = DependentLibs \
    Editor \
    Engine \
    pcalibrator \
    GIFs2PNG \
    PNG2GIFs \
    LazyFixTool \
    MusicPlayer \
    Manager \
    Maintainer

DependentLibs.file = _Libs/pge_deps.pro

Editor.file	 = Editor/pge_editor.pro
Engine.file	 = Engine/pge_engine.pro
pcalibrator.file = PlayableCalibrator/pge_calibrator.pro
GIFs2PNG.file	 = GIFs2PNG/GIFs2PNG.pro
PNG2GIFs.file	 = PNG2GIFs/png2gifs.pro
LazyFixTool.file = LazyFixTool/LazyFixTool.pro
MusicPlayer.file = MusicPlayer/pge_musplay.pro
Manager.file     = Manager/pge_manager.pro
Maintainer.file  = Maintainer/pge_maintainer.pro

configs.path = $$DESTDIR/configs
configs.files = Content/configs/*
helps.path = $$DESTDIR/help
helps.files = Content/help/*
themes.path = $$DESTDIR/themes
themes.files = Content/themes/*
calibrator_cnfs.path = $$DESTDIR/calibrator
calibrator_cnfs.files  = Content/calibrator/*

INSTALLS += configs helps themes calibrator_cnfs

noeditor: {
    SUBDIRS -= Editor
}
noengine: {
    SUBDIRS -= Engine
}
nocalibrator: {
    SUBDIRS -= pcalibrator
}
nocalibrator: {
    SUBDIRS -= pcalibrator
}
nogifs2png: {
    SUBDIRS -= GIFs2PNG
}
nopng2gifs: {
    SUBDIRS -= PNG2GIFs
}
nolazyfixtool: {
    SUBDIRS -= LazyFixTool
}
nomusicplayer: {
    SUBDIRS -= MusicPlayer
}
nomanager: {
    SUBDIRS -= Manager
}
nomaintainer: {
    SUBDIRS -= Maintainer
}

android:{
SUBDIRS -= Engine pcalibrator GIFs2PNG PNG2GIFs LazyFixTool Manager Maintainer MusicPlayer
INSTALLS -= configs helps themes calibrator_cnfs
}

DISTFILES += \
    pge_engine.supp