XAimAssist/CMakeLists.txt at main · xaprier/XAimAssist · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
cmake_minimum_required(VERSION 3.21)

project(
    XAimAssist
    VERSION 1.0.0
    LANGUAGES C CXX
    DESCRIPTION "An open-source 3D FPS aim training application built with modern C++ architecture, Qt6, and VTK rendering."
    HOMEPAGE_URL "https://github.com/xaprier/XAimAssist"
)

set(PROJECT_ORGANIZATION "xaprier")

include(CMakePackageConfigHelpers)
include(GNUInstallDirs)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
set(CMAKE_INSTALL_RPATH_USE_LINK_PATH ON)

set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTOUIC ON)
set(CMAKE_AUTORCC ON)

if(NOT CMAKE_CONFIGURATION_TYPES AND NOT CMAKE_BUILD_TYPE)
    set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type" FORCE)
endif()

option(XAIMASSIST_BUILD_TESTS "Build tests" OFF)
option(XAIMASSIST_ENABLE_DEPLOYMENT "Enable deployment install hooks" ON)

find_package(Qt6 REQUIRED COMPONENTS
    Core
    Gui
    Widgets
    Sql
    Qml
    Quick
    QuickWidgets
    QuickControls2)

find_package(VTK 9 REQUIRED COMPONENTS
    CommonColor
    CommonCore
    FiltersSources
    GUISupportQt
    InteractionStyle
    RenderingCore
    RenderingOpenGL2
)

add_subdirectory(src)

set(XAIMASSIST_CMAKE_CONFIG_INSTALL_DIR
    "${CMAKE_INSTALL_LIBDIR}/cmake/XAimAssist"
)

configure_package_config_file(
    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/XAimAssistConfig.cmake.in"
    "${CMAKE_CURRENT_BINARY_DIR}/XAimAssistConfig.cmake"
    INSTALL_DESTINATION "${XAIMASSIST_CMAKE_CONFIG_INSTALL_DIR}"
)

write_basic_package_version_file(
    "${CMAKE_CURRENT_BINARY_DIR}/XAimAssistConfigVersion.cmake"
    VERSION ${PROJECT_VERSION}
    COMPATIBILITY SameMajorVersion
)

install(
    EXPORT XAimAssistTargets
    FILE XAimAssistTargets.cmake
    NAMESPACE XAimAssist::
    DESTINATION "${XAIMASSIST_CMAKE_CONFIG_INSTALL_DIR}"
)

install(
    FILES
        "${CMAKE_CURRENT_BINARY_DIR}/XAimAssistConfig.cmake"
        "${CMAKE_CURRENT_BINARY_DIR}/XAimAssistConfigVersion.cmake"
    DESTINATION "${XAIMASSIST_CMAKE_CONFIG_INSTALL_DIR}"
)