vzaar-api-java/build.gradle at master · vzaar/vzaar-api-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
apply plugin: 'java'
apply plugin: 'groovy'
apply plugin: 'maven'
apply plugin: 'signing'
apply plugin: 'checkstyle'
apply from: "$rootDir/coverage.gradle"

Properties versionProperties = new Properties();
versionProperties.load(new File(rootDir, "src/main/resources/version.properties").newInputStream())
version = versionProperties.getProperty("version")
group = 'com.vzaar'
archivesBaseName = "vzaar-java-sdk"

signing {
    required { gradle.taskGraph.hasTask('uploadArchives') }
    sign configurations.archives
}

repositories {
    mavenCentral()
}

dependencies {
    compile 'com.fasterxml.jackson.core:jackson-databind:2.8.6'
    compile 'com.fasterxml.jackson.datatype:jackson-datatype-jsr310:2.8.6'
    compile 'org.apache.httpcomponents:httpclient:4.5.2'
    compile 'org.apache.httpcomponents:httpmime:4.5.2'

    testCompile 'org.spockframework:spock-core:1.1-groovy-2.4-rc-3'

    checkstyle('com.puppycrawl.tools:checkstyle:7.4')
}

checkstyle {
    configFile = new File(rootDir, "config/checkstyle/checkstyle.xml")
    showViolations = false
}

sourceSets {
    integrationTest {
        groovy {
            compileClasspath += main.output + test.output
            runtimeClasspath += main.output + test.output
            srcDir file('src/integration-test/groovy')
        }
        resources.srcDir file('src/integration-test/resources')
    }
}

configurations {
    integrationTestCompile.extendsFrom testCompile
    integrationTestRuntime.extendsFrom testRuntime
}

test {
    testLogging {
        events "failed"
        exceptionFormat "short"
    }
}

task integrationTest(type: Test) {
    testClassesDir = sourceSets.integrationTest.output.classesDir
    classpath = sourceSets.integrationTest.runtimeClasspath
    outputs.upToDateWhen { false }

    systemProperties = [
            vzaarClientId: System.getProperty('vzaarClientId'),
            vzaarAuthToken: System.getProperty('vzaarAuthToken'),
    ]

    jacoco {
        append = true
        destinationFile = file("$buildDir/jacoco/test.exec")
    }
}

check.dependsOn integrationTest
integrationTest.mustRunAfter test

tasks.withType(Test) {
    reports.html.destination = file("${reporting.baseDir}/${name}")
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from tasks.javadoc.destinationDir
}

task sourcesJar(type: Jar) {
    from sourceSets.main.allSource
    classifier = 'sources'
}

artifacts {
    archives jar
    archives javadocJar
    archives sourcesJar
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: project.hasProperty('ossrhUsername') ? ossrhUsername : '', password: project.hasProperty('ossrhPassword')? ossrhPassword : '')
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: (project.hasProperty('ossrhUsername') ? ossrhUsername : ''), password: (project.hasProperty('ossrhPassword')? ossrhPassword : ''))
            }

            pom.project {
               name 'vzaar-sdk-java'
               packaging 'jar'
               description 'Vzaar Client Java SDK'
               url 'https://github.com/nine-lives/vzaar-sdk-java'

               scm {
                   url 'scm:git@github.com:nine-lives/vzaar-sdk-java.git'
                   connection 'scm:git@github.com:nine-lives/vzaar-sdk-java.git'
                   developerConnection 'scm:git@github.com:nine-lives/vzaar-sdk-java.git'
               }

               licenses {
                   license {
                       name 'The MIT License (MIT)'
                       url 'https://raw.githubusercontent.com/nine-lives/vzaar-sdk-java/master/LICENSE'
                       distribution 'repo'
                   }
               }

               developers {
                   developer {
                       id 'mgsmith57'
                       name 'Marc G. Smith'
                       email 'marc@vzaar.com'
                   }
               }
           }
        }
    }
}