How to integrate nix-topology

[xdbr]

A belated Happy New Year everyone!

I'm looking for advice on how to integrate nix-topology into den. This would not only help me visualize my infrastructure, but, in the long run, could also be offered as a community-shareable battery.

I've been struggling very hard with this but still haven't been successful in integrating it and thus, I'm asking for help.

It seems pretty straightforward in the README on the repo itself (i.e. in the dropdown section named "Example flake.nix with flake-parts" here – note also that this section does not exist in the github pages!)

Furthermore note, that in the dropdown section of the README, nix-topology is offered as a flake-parts module and that there is more information available on the flake-parts website)

What I have so far works only up to a certain point. The following makes the home network appear in the visualisation and this is the furthest I've got:

{
  den,
  inputs,
  self,
  ...
}: {
  flake-file.inputs.nix-topology.url = "github:oddlama/nix-topology";

  imports = [inputs.nix-topology.flakeModule];

  den.aspects.topology = {
    OS,
    host,
    ...
  }: {
    # topology = {};
    includes = [
      # not evaluated
      {
        topology.nodes.toaster = {
          name = "My Toaster";
          deviceType = "device";
        };
      }
    ];
  };

  perSystem = {pkgs, ...}: {
    topology.modules = [
      {
        networks.home = {
          name = "Network Made by Host1";
          cidrv4 = "192.168.178.1/24";
        };
      }
      # {nixosConfigurations = self.nixosConfigurations;}
    ];
  };
}

However, I find myself unable to define additional nodes/networks/stuff as per the README locally on the host level, ideally very closely defined to a certain host.

Where and how would I integrate that into den or what am I missing?

Any help is more than welcome, thanks!

[xdbr]

Finally solved this myself...

The main issue was that not only the flake-parts module nix-topology.flakeModule needs to be imported globally but also nix-topology.nixosModules.default on every participating host.

For future reference, my current setup involves the following:

1. Include nix-topology flake-parts module

# modules/aspects/topology/topology.nix
{
  self,
  inputs,
  ...
}: {
  flake-file.inputs.nix-topology.url = "github:oddlama/nix-topology";

  imports = [inputs.nix-topology.flakeModule];

  fleet.topology = {
    OS,
    host,
    ...
  }: {
    nixos.imports = [inputs.nix-topology.nixosModules.default];
  };

  perSystem = {
    system,
    pkgs,
    ...
  }: {
    # Optional convenience package to build all diagrams
    packages.topology = self.topology.${system}.config.output;

    # Global definitions
    topology.modules = [
      {
        networks.home = {
          name = "Network Made by Host X";
          cidrv4 = "192.168.178.1/24";
        };

        nodes.toaster = {
          deviceType = "device";
          hardware.info = "ToasterMAX 3000";
        };
      }
      {nixosConfigurations = self.nixosConfigurations;}
    ];
  };
}

2. example host definition

# modules/hosts/barbara-bar/barbara-bar.nix
{
  den,
  inputs,
  __findFile,
  lib,
  ...
}: {
  den.aspects.barbara-bar = {
    includes = [
      <bootloader/grub>
      <disko/disk-profile/ext4>
      <hetzner/qemu/kernel-modules>
      <fleet/facter>
      <fleet/sops>
      # <fleet/mailserver>
      # <fleet/topology>
    ];

    nixos = {pkgs, ...}: {
      environment.systemPackages = [pkgs.hello];
    };

    homeManager.programs.direnv.enable = true;
  };
}

3. make sure that nix-topology.nixosModules.default is imported on the host

# modules/hosts/barbara-bar/topology.nix
{
  inputs,
  __findFile,
  ...
}: {
  den.aspects.barbara-bar = {
    OS,
    host,
    ...
  }: {
    # imports = [inputs.nix-topology.nixosModules.default];
    includes = [<fleet/topology>];

    # Local topology definitions for host barbara-bar
    topology = {
      # Optional explicit node for e.g. a coffee machine
      nodes.coffeemachine = {
        deviceType = "device";
        hardware.info = "Lelit Anna";
      };

      # Attach barbara to the global home network
      nodes.barbara.interfaces.lan = {
        network = "home";
      };
    };
  };
}

Currently, I'm thinking what are more den-idiomatic way could look like. Any suggestions welcome!