build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.5.9'
    id 'io.spring.dependency-management' version '1.1.7'
    id 'com.google.cloud.tools.jib' version '3.5.2'       // Jib 플러그인
}

group = 'org.sopt'
version = '0.0.1-SNAPSHOT'
description = 'poti'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-oauth2-client'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-data-redis'
    compileOnly 'org.projectlombok:lombok'
    runtimeOnly 'com.mysql:mysql-connector-j'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.springframework.security:spring-security-test'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
    testRuntimeOnly 'com.h2database:h2'

    implementation 'io.awspring.cloud:spring-cloud-aws-starter-s3:3.1.1'

    // SQL 파라미터가 '?' 대신 진짜 값으로 보이게 해주는 라이브러리 - 디버깅용
    implementation 'com.github.gavlyukovskiy:p6spy-spring-boot-starter:1.9.1'

    // jwt
    implementation 'io.jsonwebtoken:jjwt-api:0.12.3'
    runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.12.3'
    runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.12.3'

    // QueryDSL
    implementation 'com.querydsl:querydsl-jpa:5.0.0:jakarta'
    annotationProcessor "com.querydsl:querydsl-apt:5.0.0:jakarta"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"

    //한국어 특화 비속어 검사 라이브러리
    implementation 'io.github.vaneproject:badwordfiltering:1.0.0'

    // OpenFeign
    implementation 'org.springframework.cloud:spring-cloud-starter-openfeign'

    // Swagger (SpringDoc)
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.8.3'
}

ext {
    set('springCloudVersion', "2025.0.0")
}

dependencyManagement {
    imports {
        mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
    }
}

jib {
    from {
        image = 'eclipse-temurin:21-jre-alpine'
    }
    to {
        image = 'dlacofbs/poti-server'
        tags = ['latest',
                System.getenv('GITHUB_SHA')?.take(7) ?: 'dev',
                System.getenv('GITHUB_RUN_NUMBER') ?: 'local'
        ]
        auth {
            username = System.getenv('DOCKER_USERNAME') ?: 'default'
            password = System.getenv('DOCKER_PASSWORD') ?: 'default'
        }
    }
    container {
        creationTime = 'USE_CURRENT_TIMESTAMP'
        ports = ['8080']
        jvmFlags = ['-Dspring.threads.virtual.enabled=true', '-Duser.timezone=Asia/Seoul']
    }
}

tasks.named('test') {
    useJUnitPlatform()
}