mopl-backend/build.gradle at develop · team-mopl/mopl-backend · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
plugins {
    id 'java'
    id 'jacoco'
    id 'org.springframework.boot' version '3.5.11'
    id 'io.spring.dependency-management' version '1.1.7'
}

group = 'team'
version = '0.0.1-SNAPSHOT'
description = 'mopl'

repositories {
    mavenCentral()
}

bootJar {
    enabled = false
}

jar {
    enabled = false
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'java-library'
    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'
    apply plugin: 'jacoco' // jacoco

    group = 'mopl'
    version = '0.0.1-SNAPSHOT'

    java {
        sourceCompatibility = '17'
    }

    jacoco {
        toolVersion = "0.8.12"
    }

    configurations {
        compileOnly {
            extendsFrom annotationProcessor
        }
    }

    repositories {
        mavenCentral()
    }

    dependencies {
        implementation 'org.springframework.boot:spring-boot-starter'
        testImplementation 'org.springframework.boot:spring-boot-starter-test'
        testRuntimeOnly 'org.junit.platform:junit-platform-launcher'

        // lombok
        compileOnly 'org.projectlombok:lombok'
        annotationProcessor 'org.projectlombok:lombok'

        //테스트에서 lombok 사용
        testCompileOnly 'org.projectlombok:lombok'
        testAnnotationProcessor 'org.projectlombok:lombok'
    }

    tasks.named('test') {
        useJUnitPlatform()
        finalizedBy jacocoTestReport
    }

    jacocoTestReport {
        dependsOn test

        reports {
            html.required = true
            xml.required = true
            csv.required = false
        }
    }

    jacocoTestCoverageVerification {
        if (project.name == 'mopl-persistence') {
            def excludes = [
                    '**/Q*',
                    '**/rdb/global/**'
            ]
            classDirectories.setFrom(
                    files(classDirectories.files.collect { fileTree(dir: it, exclude: excludes) })
            )
        }

        violationRules {
            rule {
                limit {
                    counter = 'LINE'
                    value = 'COVEREDRATIO'
                    minimum = 0.30
                }
            }
        }
    }
}

tasks.register('jacocoRootReport', JacocoReport) {
    dependsOn subprojects.collect { it.tasks.named('test') }
    dependsOn subprojects.collect { it.tasks.named('jacocoTestReport') }

    // Avoid broad rootDir scanning to satisfy Gradle 8 task validation.
    executionData.from(subprojects.collect { it.layout.buildDirectory.file('jacoco/test.exec') })
    sourceDirectories.from(subprojects.collect { it.sourceSets.main.allSource.srcDirs })
    classDirectories.from(subprojects.collect { it.sourceSets.main.output })

    reports {
        html.required = true
        xml.required = true
        html.outputLocation = layout.buildDirectory.dir('reports/jacoco/jacocoRootReport/html')
        xml.outputLocation = layout.buildDirectory.file('reports/jacoco/jacocoRootReport/jacocoRootReport.xml')
    }
}