build.gradle

// Gradle script to build the Acorus project

plugins {
    id 'base' // to add a "clean" task to the root project
}

ext {
    jmeTarget = '' // distinguish non-JME libraries built for specific JME releases
    acorusSnapshot = '-SNAPSHOT' // for development builds
    //acorusSnapshot = '' // for release builds
    acorusVersion = '2.0.3' + jmeTarget + acorusSnapshot
}

subprojects {
    apply from: rootProject.file('common.gradle')
}

configurations.configureEach {
    resolutionStrategy.cacheChangingModulesFor 0, 'seconds' // to disable caching of snapshots
}

tasks.register('AppChooser') {
    dependsOn ':AcorusExamples:AppChooser'
    description = 'Runs the example apps.'
}

tasks.register('checkstyle') {
    dependsOn ':AcorusExamples:checkstyleMain', ':AcorusLibrary:checkstyleMain'
    description = 'Checks the style of all Java sourcecode.'
}

// Register cleanup tasks:

clean.dependsOn('cleanNodeModules')
tasks.register('cleanNodeModules', Delete) {
    delete 'node_modules'
}

// Register publishing tasks:

tasks.register('install') {
    dependsOn ':AcorusLibrary:install'
    description = 'Installs the Maven artifacts to the local repository.'
}
tasks.register('release') {
    dependsOn ':AcorusLibrary:release'
    description = 'Stages the Maven artifacts to the Central Publisher Portal.'
}