Types.fs

module LspExample.Types

open System
open System.IO
open Ionide.LanguageServerProtocol.Types

/// <summary>
/// An absolute path on the file system. Should be a real file or directory.
/// </summary>
type AbsolutePath = AbsolutePath of string

/// Functions for working with AbsolutePaths
module AbsolutePath =
    /// Handle windows path separators
    let private deDOS (path: string) =
        if Path.DirectorySeparatorChar = '\\' then
            path.Replace('\\', '/')
        else
            path
            
    let ofUri (uri: Uri) =
        uri.AbsolutePath |> Uri.UnescapeDataString |> deDOS |> AbsolutePath

    let toString (AbsolutePath path) = path

    let toUri (AbsolutePath path) =
        if Environment.OSVersion.Platform = PlatformID.Win32NT then
            $"file:///%s{path}"
        else
            $"file://%s{path}"

/// <summary>
/// Convert a file URI from the client to an absolute file path for the local file system.
/// </summary>
/// <remarks>Removes the schema and unescapes any specially encoded characters because the LSP spec does not specify if characters are encoded.</remarks>
/// <param name="uri">The file URI to convert</param>
let uriToPath (uri: string) =
    uri |> Uri.UnescapeDataString |> Uri |> AbsolutePath.ofUri

/// Active pattern to make working with .NET BCL Try* functions nicer 
let (|Success|Nothing|) (valueFound: bool, value: 'a) =
    if valueFound then Success value else Nothing

/// Construct an LSP range record
let range (startLine: int, startColumn: int) (endLine: int, endColumn: int) : Range =
    { Start =
        { Line = uint32 startLine
          Character = uint32 startColumn }
      End =
        { Line = uint32 endLine
          Character = uint32 endColumn } }

/// Holder for cached file contents that are synced from the LSP client
[<ReferenceEquality>]
type FileContent = FileContent of int * string

/// Define the abstract types of the simple demo language
module DemoLang =

    type Value =
        | Number of float
        | Text of string
        | Empty of string

    type Line =
        { Line: int
          Contents: string
          Value: Value }