Shouldn't OSSUnixSubprocess>>#isRunning answer false after resuming the image?

[tinchodias]

In the following script, a pharo process waits a os process. Then I save&quit and re-open the image, and the OS process answers it's running. I would expect a negative answer, or at least, to have another testing method that answers false. But didn't find one. Should we modify isRunning or add a new testing method?

osSubprocess :=
	OSSUnixSubprocess new
		command: 'tail';
		arguments: #('-f' '/var/log/system.log' );
		yourself.
pharoProcess := [ osSubprocess runAndWait ] fork.

"-- Accessing details in SAME session --"

osSubprocess. "OSSUnixSubprocess(Command: tail; Pid: 98737; Status: Not finished)"
pharoProcess isTerminated. "false"
osSubprocess isRunning. "true"
OSSVMProcess vmProcess childPids. "an OrderedCollection(98737)"


"-- Accessing details in ANOTHER session (after save&quit and reopen) --"

osSubprocess.  "OSSUnixSubprocess(Command: tail; Pid: 98737; Status: Not finished)"
pharoProcess isTerminated. "true"
osSubprocess isRunning. "true"
OSSVMProcess vmProcess childPids. "an OrderedCollection()"

The OSSVMProcess clean ups the collection of child processes on image resume:

startUp: resuming
	resuming ifTrue: [ self initializeVMProcessInstance ]

My opinion is that isRunning should test if its pid is included in OSSVMProcess's childPids

[tinchodias]

I'd add in OSSVMProcess:

includesChildPid: aPid

	^ childProcessList anySatisfy: [ :process | process pid = aPid ]

and make isRunning send it:

isRunning
	"Answers whether the process is still running or not (to our best knowledge)"

	^ pid notNil and: [
		self isComplete not and: [
			OSSVMProcess vmProcess includesChildPid: pid ] ]

Maybe this "to our best knowledge" warning that is present in the comment means we don't ask OSSVMProcess.

[tinchodias]

For the record, before my above proposal, I had this apparently valid alternative:

1. Add in OSSVMProcess:

isChildRunning: childPid
	"Use waitpid with WNOHANG option to know if the child process is running. 
	See: https://man7.org/linux/man-pages/man3/wait.3p.html"

	^ (self
			primitiveWaitpid: childPid
			statusPointer: nil
			options: WNOHANG) = 0

2. Modify isRunning:

isRunning
	"Answers whether the process is still running or not (to our best knowledge)"

	^ pid notNil and: [
		self isComplete not and: [
			OSSVMProcess vmProcess isChildRunning: pid ] ]

But it looks better checking at childProcessList.