Nix/NixOS deployment with Podman/Quadlet

[descention]

The following is the configuration I am using for my NixOS deployment of Drop server. This configuration uses Quadlet as that's how I wanted to deploy mine.

{ config, ... }:
let
  SERVICE="drop";
  VOLUME_DB = "${SERVICE}_db";
  VOLUME_DATA = "${SERVICE}_data";
  PORT= "8000";
  EXTERNAL_URL="https://drop.local";
  LIBRARY="/path/to/games";
in {
  virtualisation.quadlet = let
    inherit (config.virtualisation.quadlet) networks pods containers;
  in {
    containers = {
      drop-app = {
        containerConfig = {
          image = "ghcr.io/drop-oss/drop:nightly";
          publishPorts = ["${PORT}:3000"];
          volumes = [
            "${VOLUME_DATA}:/data"
            "${LIBRARY}:/library:ro"
          ];
          environments = {
            DATABASE_URL="postgres://drop:drop@drop-db:5432/drop";
            EXTERNAL_URL=EXTERNAL_URL;
          };
          networks = [ networks."${SERVICE}".ref ];
        };
        unitConfig = {
          After = containers.drop-db.ref;
          Wants = containers.drop-db.ref;
        };
      };
      drop-db = {
        containerConfig = {
          image = "postgres:alpine";
          volumes = [
            "${VOLUME_DB}:/var/lib/postgresql/data"
          ];
          environments = {
            POSTGRES_PASSWORD="drop";
            POSTGRES_USER="drop";
            POSTGRES_DB="drop";
          };
          networks = [ networks.${SERVICE}.ref ];
          healthCmd = "pg_isready -d drop -U drop";
          healthInterval = "30s";
          healthRetries = 5;
          healthStartPeriod = "10s";
          healthTimeout = "60s";
          notify = "healthy";
        };
        unitConfig = {
          PartOf = [ containers.drop-app.ref ];
          BindsTo = [ containers.drop-app.ref ];
        };
      };
    };
    networks = {
      "${SERVICE}".networkConfig = {
        internal = false;
        name = "${SERVICE}-net";
      };
    };
  };
}

[Huskydog9988]

As a quick note, make sure to include the options below as they help it handle SIGINT signals. (Basically shutdown the shutdown signal.)

stdin_open: true
tty: true 
init: true

[descention]

I found RunInit for Quadlet. I couldn't find anything specific to stdin_open or tty.

[Huskydog9988]

You can find more about that stuff and how it relates to docker https://github.com/nodejs/docker-node/blob/main/docs/BestPractices.md#handling-kernel-signals. Not sure how applicable it is to podman though, thought quadlet was a docker wraper.