chatbot.tf

resource "aws_iam_role" "chatbot" {
  name               = local.resource_name
  tags               = local.tags
  assume_role_policy = data.aws_iam_policy_document.chatbot_assume.json
}

data "aws_iam_policy_document" "chatbot_assume" {
  statement {
    effect  = "Allow"
    actions = ["sts:AssumeRole"]

    principals {
      type        = "Service"
      identifiers = ["chatbot.amazonaws.com"]
    }
  }
}

resource "aws_iam_role_policy" "chatbot" {
  name   = "chatbot-notifications"
  role   = aws_iam_role.chatbot.id
  policy = data.aws_iam_policy_document.chatbot.json
}

data "aws_iam_policy_document" "chatbot" {
  statement {
    effect    = "Allow"
    resources = ["*"]

    actions = [
      "cloudwatch:Describe*",
      "cloudwatch:Get*",
      "cloudwatch:List*",
    ]
  }
}

resource "aws_chatbot_slack_channel_configuration" "this" {
  configuration_name = local.resource_name
  iam_role_arn       = aws_iam_role.chatbot.arn
  slack_team_id      = var.slack_workspace
  slack_channel_id   = var.channel_name
  sns_topic_arns     = [aws_sns_topic.notifications.arn]
  tags               = local.tags
}