aws-existing-network/subnets.tf at master · nullstone-modules/aws-existing-network · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
data "aws_subnets" "all" {
  filter {
    name   = "vpc-id"
    values = [data.aws_vpc.this.id]
  }
}

data "aws_route_tables" "all" {
  for_each = toset(data.aws_subnets.all.ids)
  filter {
    name   = "association.subnet-id"
    values = [each.value]
  }
}

data "aws_route_table" "all" {
  for_each       = { for subnet_id, rtbs in data.aws_route_tables.all : subnet_id => rtbs.ids if length(rtbs.ids) > 0 }
  route_table_id = tolist(each.value)[0]
}

locals {
  routes = flatten([for subnet_id, rtb in data.aws_route_table.all : [for rt in rtb.routes : {
    id             = rtb.id
    gateway_id     = rt.gateway_id
    nat_gateway_id = rt.nat_gateway_id
    subnet_id      = subnet_id
  }]])
  all_subnet_ids  = data.aws_subnets.all.ids
  public_subnets  = toset(compact([for rt in local.routes : (rt.gateway_id != "" ? rt.subnet_id : "")]))
  private_subnets = toset(compact([for rt in local.routes : (rt.nat_gateway_id != "" ? rt.subnet_id : "")]))
  intra_subnets   = setsubtract(setsubtract(local.all_subnet_ids, local.public_subnets), local.private_subnets)
}

data "aws_subnet" "public" {
  for_each = local.public_subnets
  id       = each.value
}

data "aws_subnet" "private" {
  for_each = local.private_subnets
  id       = each.value
}

data "aws_subnet" "intra" {
  for_each = local.intra_subnets
  id       = each.value
}