nix-conf/flake.nix at main · nathan-gs/nix-conf · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
    nixpkgs-unstable.url = "github:NixOS/nixpkgs/nixos-unstable";
    secrets = {
      url = "git+file:///etc/nixos/secrets";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    photoprism-slideshow = {
      url = "github:nathan-gs/photoprism-slideshow";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixos-hardware = {
      url = "github:NixOS/nixos-hardware/master";
    };
    nixos-vscode-server = {
      url = "github:nix-community/nixos-vscode-server";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, nixpkgs-unstable, secrets, photoprism-slideshow, nixos-hardware, nixos-vscode-server, ... }:
    let
      overlay = final: prev: { nixpkgs-unstable = nixpkgs-unstable.legacyPackages.${prev.stdenv.hostPlatform.system}; };
      overlayModule = ({ config, pkgs, ... }: { nixpkgs.overlays = [ overlay ]; });
      platformModule = { nixpkgs.hostPlatform = "x86_64-linux"; };

    in
    {

      nixosConfigurations = {
        nhtpc = nixpkgs.lib.nixosSystem {
          modules = [
            # Point this to your original configuration.
            ./computers/nhtpc.nix
            secrets.nixosModules.secrets
            photoprism-slideshow.nixosModules.photoprism-slideshow
            nixos-vscode-server.nixosModules.default
            overlayModule
            platformModule
          ];

          specialArgs.channels = { inherit nixpkgs nixpkgs-unstable; };
        };

        ngo = nixpkgs.lib.nixosSystem {
          modules = [
            # Point this to your original configuration.
            ./computers/ngo.nix
            secrets.nixosModules.secrets
            nixos-hardware.nixosModules.microsoft-surface-go
            overlayModule
            platformModule
          ];

          specialArgs.channels = { inherit nixpkgs nixpkgs-unstable; };
        };

        nnas = nixpkgs.lib.nixosSystem {
          modules = [
            # Point this to your original configuration.
            ./computers/nnas.nix
            secrets.nixosModules.secrets
            overlayModule
            platformModule
          ];
        };
      };
    };
}