nov-open-reader/build.gradle.kts at main · lcacheux/nov-open-reader · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
import java.util.Properties

plugins {
    alias(libs.plugins.kotlin.multiplatform) apply false
    alias(libs.plugins.android.application) apply false
    alias(libs.plugins.android.library) apply false
    alias(libs.plugins.kotlin.android) apply false
    alias(libs.plugins.kotlin.jvm) apply false
    alias(libs.plugins.jetbrains.compose) apply false
    alias(libs.plugins.compose.compiler) apply false
    alias(libs.plugins.hilt.android) apply false
    alias(libs.plugins.ksp) apply false
    alias(libs.plugins.sonarqube)
    signing
}

val localProperties by extra { Properties().apply {
    if (File("$rootDir/local.properties").exists())
        load(File("$rootDir/local.properties").inputStream())
} }

val gpgSigningAvailable = listOf("gpgSigningKey", "gpgSigningPass").map {
    localProperties.containsKey(it)
}.all { it }

val signingIfAvailable by extra {
    { publication: Publication ->
        if (gpgSigningAvailable) {
            extensions.create<SigningExtension>("sign${publication.name}").apply {
                sign(publication)
                useInMemoryPgpKeys(
                    localProperties["gpgSigningKey"] as String,
                    localProperties["gpgSigningPass"] as String
                )
            }
        }
    }
}

sonar {
    properties {
        property("sonar.projectKey", "lcacheux_nov-open-reader")
        property("sonar.organization", "lcacheux")
    }
}

val nvplibVersion: String? by extra {
    providers.exec {
        commandLine("git", "describe", "--tags", "--match", "nvplib-*")
    }.standardOutput.asText.get().trim().removePrefix("nvplib-")
}