raytracer/matrix.ss at dev · laqrix/raytracer · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
(define (make-matrix m n initializer)
  (let ([store (make-vector (fx* m n))])
    (define (index i j)
      (unless (and (fx<= 1 i m) (fx<= 1 j n))
        (errorf #f "matrix index (~a, ~a) out of bounds (~a, ~a)" i j m n))
      (fx+ (fx* (fx- i 1) n) j -1))
    (initializer m n
      (case-lambda
       [(i j) (vector-ref store (index i j))]
       [(i j x) (vector-set! store (index i j) x)]))
    (case-lambda
     [() (values m n)]
     [(i j) (vector-ref store (index i j))])))

(define (matrix-dimensions a) (a))

(define (matrix->list a)
  (let-values ([(m n) (matrix-dimensions a)])
    (let f1 ([i m] [rows '()])
      (if (fx> i 0)
          (let f2 ([j n] [row '()])
            (if (fx> j 0)
                (f2 (fx- j 1) (cons (a i j) row))
                (f1 (fx- i 1) (cons row rows))))
          rows))))

(define (list->matrix ls)
  (make-matrix (length ls) (length (car ls))
    (lambda (m n a)
      (do ([i 1 (fx+ i 1)] [rows ls (cdr rows)]) ((fx> i m))
        (do ([j 1 (fx+ j 1)] [cols (car rows) (cdr cols)]) ((fx> j n))
          (a i j (car cols)))))))

(define (matrix-identity n)
  (make-matrix n n
    (lambda (m n a)
      (do ([i 1 (fx+ i 1)]) ((fx> i m))
        (a i i 1)))))

(define matrix-add
  (case-lambda
   [(a1) a1]
   [(a1 a2)
    (let-values ([(m1 n1) (matrix-dimensions a1)]
                 [(m2 n2) (matrix-dimensions a2)])
      (unless (and (fx= m1 m2) (fx= n1 n2))
        (errorf 'matrix-add "mismatched sizes"))
      (make-matrix m1 n1
        (lambda (m n a)
          (do ([i 1 (fx+ i 1)]) ((fx> i m))
            (do ([j 1 (fx+ j 1)]) ((fx> j n))
              (a i j (+ (a1 i j) (a2 i j))))))))]
   [(a1 a2 . rest) (apply matrix-add (matrix-add a1 a2) rest)]))

(define matrix-sub
  (case-lambda
   [(a1 a2)
    (let-values ([(m1 n1) (matrix-dimensions a1)]
                 [(m2 n2) (matrix-dimensions a2)])
      (unless (and (fx= m1 m2) (fx= n1 n2))
        (errorf 'matrix-sub "mismatched sizes"))
      (make-matrix m1 n1
        (lambda (m n a)
          (do ([i 1 (fx+ i 1)]) ((fx> i m))
            (do ([j 1 (fx+ j 1)]) ((fx> j n))
              (a i j (- (a1 i j) (a2 i j))))))))]
   [(a1 a2 . rest) (apply matrix-sub (matrix-sub a1 a2) rest)]))

(define matrix-mul
  (case-lambda
   [(a1) a1]
   [(a1 a2)
    (let-values ([(m1 n1) (matrix-dimensions a1)]
                 [(m2 n2) (matrix-dimensions a2)])
      (unless (fx= n1 m2)
        (errorf 'matrix-mul "mismatched sizes"))
      (make-matrix m1 n2
        (lambda (m n a)
          (do ([i 1 (fx+ i 1)]) ((fx> i m))
            (do ([j 1 (fx+ j 1)]) ((fx> j n))
              (let dot ([k 1] [sum 0])
                (if (fx> k n1)
                    (a i j sum)
                    (dot (fx+ k 1) (+ (* (a1 i k) (a2 k j)) sum)))))))))]
   [(a1 a2 . rest) (apply matrix-mul (matrix-mul a1 a2) rest)]))

(define (matrix-transpose a)
  (let-values ([(m n) (matrix-dimensions a)])
    (make-matrix n m
      (lambda (n m t)
        (do ([i 1 (fx+ i 1)]) ((fx> i m))
          (do ([j 1 (fx+ j 1)]) ((fx> j n))
            (t j i (a i j))))))))

(define (ludcmp a0)
  (let-values ([(m n) (matrix-dimensions a0)])
    (unless (fx= m n)
      (errorf 'ludcmp "matrix must be square"))
    (let* ([indx (make-vector n)]
           [d 1]
           [a
            (make-matrix m n
              (lambda (m n a)
                (let ([vv (make-vector n)])
                  (define (set-vv! i x) (vector-set! vv (fx- i 1) x))
                  (define (vv-ref i) (vector-ref vv (fx- i 1)))
                  ;; Loop over rows to get the implicit scaling information,
                  ;; copying a0 into a along the way
                  (do ([i 1 (fx+ i 1)]) ((fx> i n))
                    (let lp ([j 1] [big 0])
                      (cond
                       [(fx<= j n)
                        (let ([x (a0 i j)])
                          (a i j x)
                          (lp (fx+ j 1) (max (abs x) big)))]
                       [(zero? big) (errorf 'ludcmp "singular matrix")]
                       [else (set-vv! i (/ big))])))
                  ;; Loop over columns of Crout's method
                  (do ([j 1 (fx+ j 1)]) ((fx> j n))
                    (do ([i 1 (fx+ i 1)]) ((fx>= i j))
                      (let lp ([k 1] [sum (a i j)])
                        (if (fx< k i)
                            (lp (fx+ k 1) (- sum (* (a i k) (a k j))))
                            (a i j sum))))
                    (let lp1 ([i j] [big 0] [imax j])
                      (cond
                       [(fx<= i n)
                        (let lp2 ([k 1] [sum (a i j)])
                          (cond
                           [(fx< k j)
                            (lp2 (fx+ k 1) (- sum (* (a i k) (a k j))))]
                           [else
                            (a i j sum)
                            (let ([dum (* (vv-ref i) (abs sum))])
                              (if (>= dum big)
                                  (lp1 (fx+ i 1) dum i)
                                  (lp1 (fx+ i 1) big imax)))]))]
                       [else
                        (unless (fx= j imax)
                          (do ([k 1 (fx+ k 1)]) ((fx> k n))
                            (let ([dum (a imax k)])
                              (a imax k (a j k))
                              (a j k dum)))
                          (set! d (- d))
                          (set-vv! imax (vv-ref j)))
                        (vector-set! indx (fx- j 1) imax)
                        (when (zero? (a j j))
                          (errorf 'ludcmp "singular matrix"))
                        (unless (fx= j n)
                          (let ([pivot (/ (a j j))])
                            (do ([i (fx+ j 1) (fx+ i 1)]) ((fx> i n))
                              (a i j (* (a i j) pivot)))))]))))))])
      (values a indx d))))

(define (lubksb a indx b)
  (let-values ([(m n) (matrix-dimensions a)])
    (unless (fx= m n)
      (errorf 'lubksb "matrix must be square"))
    (let lp ([i 1] [ii #f])
      (when (fx<= i n)
        (let* ([ip (vector-ref indx (fx- i 1))]
               [sum (vector-ref b (fx- ip 1))])
          (vector-set! b (fx- ip 1) (vector-ref b (fx- i 1)))
          (if ii
              (let lp2 ([j ii] [sum sum])
                (if (fx<= j (fx- i 1))
                    (lp2 (fx+ j 1)
                      (- sum (* (a i j) (vector-ref b (fx- j 1)))))
                    (begin
                      (vector-set! b (fx- i 1) sum)
                      (lp (fx+ i 1) ii))))
              (begin
                (vector-set! b (fx- i 1) sum)
                (lp (fx+ i 1) (if (zero? sum) ii i)))))))
    (do ([i n (fx- i 1)]) ((fx= i 0))
      (let lp ([j (fx+ i 1)] [sum (vector-ref b (fx- i 1))])
        (if (fx<= j n)
            (lp (fx+ j 1) (- sum (* (a i j) (vector-ref b (fx- j 1)))))
            (vector-set! b (fx- i 1) (/ sum (a i i)))))))
  b)

(define (matrix-inverse a)
  (let-values ([(m n) (matrix-dimensions a)]
               [(a indx d) (ludcmp a)])
    (make-matrix m n
      (lambda (m n y)
        (do ([j 1 (fx+ j 1)]) ((fx> j n))
          (let ([col (make-vector n 0)])
            (vector-set! col (fx- j 1) 1)
            (lubksb a indx col)
            (do ([i 1 (fx+ i 1)]) ((fx> i n))
              (y i j (vector-ref col (fx- i 1))))))))))