mobile-sdk-android/build.gradle.kts at master · jump-sdk/mobile-sdk-android · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
plugins {
    kotlin("multiplatform") version libs.versions.kotlin.get() apply false
    kotlin("plugin.serialization") version libs.versions.kotlin.get() apply false
    id("org.jetbrains.kotlin.android") version libs.versions.kotlin.get() apply false
    id("com.android.library") version libs.versions.android.gradle.plugin.get() apply false
    id("com.android.application") version libs.versions.android.gradle.plugin apply false
    id("io.gitlab.arturbosch.detekt") version libs.versions.detekt.get()
    id("org.sonarqube") version "4.4.1.3373"
    alias(libs.plugins.gradleVersions)
    id("org.jetbrains.dokka") version "1.9.10"
}

allprojects {
    repositories {
        google()
        mavenCentral()
        gradlePluginPortal()
        maven("https://jitpack.io") {
            content {
                includeGroup("com.github.hbmartin")
            }
        }
        maven("https://oss.sonatype.org/content/repositories/snapshots/") {
            content {
                includeGroup("app.cash.paparazzi")
            }
        }
        maven("https://androidx.dev/storage/compose-compiler/repository/") {
            content {
                includeGroup("androidx.compose.compiler")
            }
        }
    }
    apply(plugin = "io.gitlab.arturbosch.detekt")
    detekt {
        config.setFrom(files(rootProject.file("detekt.yml")))
        reports {
            xml.required.set(true)
            txt.required.set(false)
            html.required.set(false)
            sarif.required.set(false)
            md.required.set(false)
        }
    }
    dependencies {
        val detektVersion = rootProject.libs.versions.detekt.get()
        detektPlugins("ru.kode:detekt-rules-compose:1.3.0")
        detektPlugins("io.nlopez.compose.rules:detekt:0.3.3")
        detektPlugins("io.gitlab.arturbosch.detekt:detekt-rules-libraries:$detektVersion")
        detektPlugins("io.gitlab.arturbosch.detekt:detekt-formatting:$detektVersion")
        detektPlugins("com.braisgabin.detekt:kotlin-compiler-wrapper:0.0.4")
        detektPlugins("com.github.hbmartin:hbmartin-detekt-rules:0.1.3")
    }
}

sonar {
    properties {
        property("sonar.projectKey", "jump-sdk_mobile-sdk-android")
        property("sonar.organization", "jump-sdk")
        property("sonar.host.url", "https://sonarcloud.io")
        property("sonar.kotlin.source.version", libs.versions.kotlin.get())
        property("sonar.pullrequest.github.summary_comment", "true")
    }
}

tasks.withType<com.github.benmanes.gradle.versions.updates.DependencyUpdatesTask> {
    checkForGradleUpdate = true
    rejectVersionIf {
        listOf("2.0.0-Beta1", "-station-", "-alpha", "-dev-").any { word ->
            candidate.version.contains(word)
        }
    }
}