default.nix

{ lib ? import ./lib/lib.nix { } }:

let
  parser = import ./core/xml-parser.nix { inherit lib; };
  # Use the bundled XML
  specXml = builtins.readFile ./data/x86_64.xml;
  spec = parser.parseInstructions specXml;
  
  assembler = import ./core/assembler.nix { inherit lib spec; };
  elf = import ./core/elf.nix { inherit lib; };
  syntax = import ./frontend/syntax.nix { inherit lib; };
  compiler = import ./frontend/compiler.nix { inherit lib; };

  # (10 + 32) -> print "42\n" -> exit(42)
  expr = [ "seq"
    [ "lit" 10 ]
    [ "lit" 32 ]
    [ "add" ]
    [ "print" ]
    [ "exit" ]
  ];

  asm = compiler.compile expr;
  instructions = syntax.parseLines asm;
  code = assembler.assemble instructions;

  headerSize = 64 + 56;
  fileSize = headerSize + (lib.length code);
  vaddr = 4194304; # 0x400000
  entry = vaddr + headerSize;

  elfHeader = elf.makeElfHeader entry 64;
  progHeader = elf.makeProgramHeader 0 vaddr fileSize;

  allBytes = elfHeader ++ progHeader ++ code;

  # Helper to convert byte list to hex string for emitter
  toHex = bytes: lib.concatMapStrings (b: lib.fixedWidthString 2 "0" (lib.toHexString b)) bytes;

  # Raw derivation
  system = builtins.currentSystem or "x86_64-linux";
  
in
builtins.derivation {
  name = "test-elf";
  inherit system;
  # Use our 360-byte hex emitter as the builder
  builder = ./bin/emitter-bin;
  args = [ (toHex allBytes) ];
}