objects/delta-loop.scad at main · jflinchbaugh/objects · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
antenna_diameter = 10.5; // mm
antenna_depth = 15; // mm
antenna_angle = 45; // degrees
antenna_offset = 15; // mm
spike_diameter = 12; // mm
side_thickness = 5; // mm
radius = 2;

$fn=24;

difference() {
  minkowski() {
    hull() {
      translate([antenna_offset, 0, 0]) {
        rotate([0,antenna_angle,0]) {
          cylinder(d=antenna_diameter + side_thickness * 2 - 2 * radius,
                  h=antenna_depth-0.1 - 2 * radius,
                  center = true);
        }
      }

      translate([-1 * antenna_offset, 0, 0]) {
        rotate([0,-1 * antenna_angle,0]) {
          cylinder(d=antenna_diameter + side_thickness * 2 - 2 * radius,
                  h=antenna_depth -0.1 - 2 * radius,
                  center = true);
        }
      }

      translate([0, 0, -1 * (antenna_diameter + side_thickness + antenna_depth)]) {
        cylinder(
                d=antenna_diameter + side_thickness * 2,
                h=0.1,
                center = true);
      }
    }
    sphere(r=radius);
  }

  // holes
  union() {
    translate([antenna_offset, 0, 0]) {
      rotate([0,antenna_angle,0]) {
        cylinder(d=antenna_diameter, h=antenna_depth, center = true);
      }
    }

    translate([-1 * antenna_offset, 0, 0]) {
      rotate([0,-1 * antenna_angle,0]) {
        cylinder(d=antenna_diameter, h=antenna_depth, center = true);
      }
    }


    cylinder(d=spike_diameter, h=100, center = true);
  }
}