Add IpInfoLite to support Lite API (#17)

* Fix tests not making requests

* Fix linting issues

* Add linting and remove unnecessary ACTIONS_ALLOW_USE_UNSECURE_NODE_VERSION env var in CI

* Add support for Lite API

* Update README.md

* Fix workflow

Author: silvanocerza

.github/workflows/ci.yaml

@@ -2,23 +2,39 @@ name: CI
 
 on: [push, pull_request]
 
-env:
-  ACTIONS_ALLOW_USE_UNSECURE_NODE_VERSION: true
-
 jobs:
   build:
     runs-on: ubuntu-latest
     strategy:
       matrix:
-        otp: [21.3, 22.0.7, 22.3, 23.0.4, 23.2.7.0, 24.0]
+        otp:
+          - "21"
+          - "22"
+          - "23"
+          - "24"
+          - "25"
+          - "26"
+          - "27"
+          - "28"
+
     container:
       image: erlang:${{ matrix.otp }}-alpine
+
     steps:
       - name: Checkout
         uses: actions/checkout@v3
+
       - name: Compile
         run: rebar3 compile
+
+      - name: Linting
+        # Linting works only with latest version
+        if: ${{ matrix.otp == '28' }}
+        run: rebar3 lint
+
       - name: Tests
+        env:
+          IPINFO_TOKEN: ${{ secrets.IPINFO_TOKEN }}
         run: |
           rebar3 xref
           rebar3 dialyzer

README.md

@@ -19,7 +19,7 @@ You'll need an IPinfo API access token, which you can get by signing up for a fr
 
 The free plan is limited to 50,000 requests per month, and doesn't include some of the data fields such as IP type and company data. To enable all the data fields and additional request volumes see [https://ipinfo.io/pricing](https://ipinfo.io/pricing).
 
-⚠️ Note: This library does not currently support our newest free API https://ipinfo.io/lite. If you’d like to use IPinfo Lite, you can call the [endpoint directly](https://ipinfo.io/developers/lite-api) using your preferred HTTP client. Developers are also welcome to contribute support for Lite by submitting a pull request.
+The library also supports the Lite API, see the [Lite API section](#lite-api) for more info.
 
 ## Installation
 
@@ -60,7 +60,7 @@ Add this line to your application's `rebar.config`:
                 #{<<"code">> => <<"AF">>,<<"name">> => <<"Africa">>},
             <<"ID">> =>
                 #{<<"code">> => <<"AS">>,<<"name">> => <<"Asia">>},
-            <<"QA">> => 
+            <<"QA">> =>
                 #{<<"code">> => <<"AS">>,<<"name">> => <<"Asia">>},
             <<"LC">> =>
                 #{<<"code">> => <<"NA">>,<<"name">> => <<"North America">>},
@@ -166,7 +166,7 @@ Add this line to your application's `rebar.config`:
                   <<"unicode">> => <<"U+1F1F5 U+1F1EB">>},
             <<"CV">> =>
                 #{<<"emoji">> => <<240,159,135,168,240,159,135,187>>,
-                  <<"unicode">> => <<"U+1F1E8 U+1F1FB">>}, 
+                  <<"unicode">> => <<"U+1F1E8 U+1F1FB">>},
             <<"CG">> =>
                 #{<<"emoji">> => <<240,159,135,168,240,159,135,172>>,
                   <<"unicode">> => <<"U+1F1E8 U+1F1EC">>},
@@ -240,7 +240,7 @@ Add this line to your application's `rebar.config`:
                 #{<<"emoji">> => <<240,159,135,191,240,159,135,178>>,
                   <<"unicode">> => <<"U+1F1FF U+1F1F2">>},...},
       country_flag_base_url =>
-          <<"https://cdn.ipinfo.io/static/images/countries-flags/">>, 
+          <<"https://cdn.ipinfo.io/static/images/countries-flags/">>,
       eu_countries =>
           [<<"IE">>,<<"AT">>,<<"LT">>,<<"LU">>,<<"LV">>,<<"DE">>,
            <<"DK">>,<<"SE">>,<<"SI">>,<<"SK">>,<<"CZ">>,<<"CY">>,
@@ -315,6 +315,23 @@ def current_ip() do
 end
 ```
 
+## Lite API
+
+The library gives the possibility to use the [Lite API](https://ipinfo.io/developers/lite-api) too, authentication with your token is still required.
+
+The returned details are slightly different from the Core API.
+
+```erlang
+Token = <<"TOKEN">>.
+{ok, IpInfoLite} = ipinfo_lite:create(Token).
+{ok, #{
+    <<"country_code">> := CountryCode,
+    <<"country">> := Country
+} } = ipinfo_lite:details(IpInfoLite, <<"8.8.8.8">>).
+io:format(CountryCode). %% US
+io:format(Country). %% United States
+```
+
 ## Other Libraries
 
 There are official [IPinfo client libraries](https://ipinfo.io/developers/libraries) available for many languages including PHP, Go, Java, Ruby, and many popular frameworks such as Django, Rails, and Laravel. There are also many third-party libraries and integrations available for our API.

config/test.config

@@ -1,5 +1,3 @@
 [
-    {ipinfo, [
-        {base_url, <<"http://localhost:32002">>}
-    ]}
+    {ipinfo, []}
 ].

elvis.config

@@ -7,7 +7,7 @@
                 ruleset => erl_files,
                 rules   => [
                     {elvis_style, function_naming_convention, #{
-                        ignore => [ipinfo],
+                        ignore => [ipinfo, ipinfo_lite],
                         regex => "^([a-z][a-z0-9]*_?)*$"
                     }}
                 ]

src/ipinfo.erl

@@ -19,7 +19,8 @@
 -define(DEFAULT_COUNTRY_FLAG_FILE, "flags.json").
 -define(DEFAULT_COUNTRY_CURRENCY_FILE, "currency.json").
 -define(DEFAULT_CONTINENT_FILE, "continent.json").
--define(DEFAULT_COUNTRY_FLAG_BASE_URL, <<"https://cdn.ipinfo.io/static/images/countries-flags/">>).
+-define(DEFAULT_COUNTRY_FLAG_BASE_URL,
+    <<"https://cdn.ipinfo.io/static/images/countries-flags/">>).
 -define(DEFAULT_BASE_URL, <<"https://ipinfo.io">>).
 -define(DEFAULT_TIMEOUT, timer:seconds(5)).
 -define(DEFAULT_CACHE_TTL_SECONDS, (24 * 60 * 60)).
@@ -97,49 +98,73 @@ create(AccessToken, Settings) ->
         filename:join(code:priv_dir(ipinfo), ?DEFAULT_COUNTRY_CURRENCY_FILE)),
     ContinentsFile = get_config(continents, Settings,
         filename:join(code:priv_dir(ipinfo), ?DEFAULT_CONTINENT_FILE)),
-    CountryFlagBaseUrl = get_config(country_flag_base_url, Settings, ?DEFAULT_COUNTRY_FLAG_BASE_URL),
+    CountryFlagBaseUrl = get_config(country_flag_base_url, Settings,
+        ?DEFAULT_COUNTRY_FLAG_BASE_URL),
     BaseUrl = get_config(base_url, Settings, ?DEFAULT_BASE_URL),
     Timeout = get_config(timeout, Settings, ?DEFAULT_TIMEOUT),
     CacheTtl = get_config(cache_ttl, Settings, ?DEFAULT_CACHE_TTL_SECONDS),
-    case read_json(CountriesFile) of
-        {ok, Countries} ->
-            case read_json(EuCountriesFile) of
-                {ok, EuCountries} ->
-                    case read_json(CountriesFlagsFile) of 
-                        {ok, CountriesFlags} ->
-                            case read_json(CountriesCurrenciesFile) of
-                                {ok, CountriesCurrencies} ->
-                                    case read_json(ContinentsFile) of 
-                                        {ok, Continents} ->
-                                            {ok, Cache} = ipinfo_cache:create(CacheTtl),
-                                            {ok, new(#{
-                                                access_token          => AccessToken,
-                                                base_url              => BaseUrl,
-                                                timeout               => Timeout,
-                                                cache                 => Cache,
-                                                countries             => Countries,
-                                                eu_countries          => EuCountries,
-                                                countries_flags       => CountriesFlags,
-                                                country_flag_base_url => CountryFlagBaseUrl,
-                                                countries_currencies  => CountriesCurrencies,
-                                                continents            => Continents
-                                            })};
-                                        {error, Error} ->
-                                            {error, Error}
-                                    end;
-                                {error, Error} ->
-                                    {error, Error}
-                            end;
-                        {error, Error} ->
-                            {error, Error}
-                    end;
-                {error, Error} ->
-                    {error, Error}
-            end;
+    create_with_files(AccessToken, BaseUrl, Timeout, CacheTtl, CountriesFile,
+        EuCountriesFile, CountriesFlagsFile, CountriesCurrenciesFile,
+        ContinentsFile, CountryFlagBaseUrl).
+
+create_with_files(AccessToken, BaseUrl, Timeout, CacheTtl, CountriesFile,
+    EuCountriesFile, CountriesFlagsFile, CountriesCurrenciesFile,
+    ContinentsFile, CountryFlagBaseUrl) ->
+    Files = [
+        CountriesFile,
+        EuCountriesFile,
+        CountriesFlagsFile,
+        CountriesCurrenciesFile,
+        ContinentsFile
+    ],
+    case read_json_files(Files) of
+        {ok, [Countries, EuCountries, CountriesFlags, CountriesCurrencies, Continents]} ->
+            create_ipinfo_struct(
+                AccessToken,
+                BaseUrl,
+                Timeout,
+                CacheTtl,
+                Countries,
+                EuCountries,
+                CountriesFlags,
+                CountriesCurrencies,
+                Continents,
+                CountryFlagBaseUrl
+            );
+        {error, Reason} ->
+            {error, Reason}
+    end.
+
+read_json_files(Files) ->
+    read_json_files(Files, []).
+
+read_json_files([], Acc) ->
+    {ok, lists:reverse(Acc)};
+read_json_files([File | Rest], Acc) ->
+    case read_json(File) of
+        {ok, Data} ->
+            read_json_files(Rest, [Data | Acc]);
         {error, Reason} ->
             {error, Reason}
     end.
 
+create_ipinfo_struct(AccessToken, BaseUrl, Timeout, CacheTtl, Countries,
+    EuCountries, CountriesFlags, CountriesCurrencies, Continents,
+    CountryFlagBaseUrl) ->
+    {ok, Cache} = ipinfo_cache:create(CacheTtl),
+    {ok, new(#{
+        access_token          => AccessToken,
+        base_url              => BaseUrl,
+        timeout               => Timeout,
+        cache                 => Cache,
+        countries             => Countries,
+        eu_countries          => EuCountries,
+        countries_flags       => CountriesFlags,
+        country_flag_base_url => CountryFlagBaseUrl,
+        countries_currencies  => CountriesCurrencies,
+        continents            => Continents
+    })}.
+
 details(IpInfo) ->
     details(IpInfo, nil).
 
@@ -151,19 +176,42 @@ details(#{cache := Cache,
     countries_currencies := CountriesCurrencies,
     continents := Continents
 } = IpInfo, IpAddress) ->
+    case get_details(Cache, IpInfo, IpAddress) of
+        {ok, Details} ->
+            {ok, enrich_details(Details, Countries, EuCountries,
+                CountriesFlags, CountryFlagBaseUrl, CountriesCurrencies,
+                Continents)};
+        {error, Reason} ->
+            {error, Reason}
+    end.
+
+get_details(Cache, IpInfo, IpAddress) ->
     case ipinfo_cache:get(Cache, IpAddress) of
         {ok, Details} ->
-            {ok, put_geo(put_country_name(put_is_eu(put_country_flag_url(put_country_flag(put_country_currency(put_continent(Details, Continents),CountriesCurrencies), CountriesFlags),CountryFlagBaseUrl), EuCountries), Countries))};
+            {ok, Details};
         error ->
             case ipinfo_http:request_details(IpInfo, IpAddress) of
                 {ok, Details} ->
                     ok = ipinfo_cache:add(Cache, IpAddress, Details),
-                    {ok, put_geo(put_country_name(put_is_eu(put_country_flag_url(put_country_flag(put_country_currency(put_continent(Details, Continents),CountriesCurrencies), CountriesFlags),CountryFlagBaseUrl), EuCountries), Countries))};
+                    {ok, Details};
                 {error, Reason} ->
                     {error, Reason}
             end
     end.
 
+enrich_details(Details, Countries, EuCountries, CountriesFlags,
+    CountryFlagBaseUrl, CountriesCurrencies, Continents) ->
+    Enrichers = [
+        fun(D) -> put_continent(D, Continents) end,
+        fun(D) -> put_country_currency(D, CountriesCurrencies) end,
+        fun(D) -> put_country_flag(D, CountriesFlags) end,
+        fun(D) -> put_country_flag_url(D, CountryFlagBaseUrl) end,
+        fun(D) -> put_is_eu(D, EuCountries) end,
+        fun(D) -> put_country_name(D, Countries) end,
+        fun put_geo/1
+    ],
+    lists:foldl(fun(F, Acc) -> F(Acc) end, Details, Enrichers).
+
 put_country_name(#{country := Country} = Details, Countries) ->
     case maps:find(Country, Countries) of
         {ok, CountryName} ->
@@ -185,7 +233,8 @@ put_country_flag(Details, _CountriesFlags) ->
     Details.
 
 put_country_flag_url(#{country := Country} = Details, CountryFlagBaseUrl) ->
-    CountryFlagUrl = filename:join(CountryFlagBaseUrl, binary_to_list(Country) ++ ".svg"),
+    CountryFlagUrl = filename:join(CountryFlagBaseUrl,
+        binary_to_list(Country) ++ ".svg"),
     maps:put(country_flag_url, CountryFlagUrl, Details);
 put_country_flag_url(Details, _CountryFlagBaseUrl) ->
     Details.
@@ -230,7 +279,8 @@ put_geo(Details) ->
     Details.
 
 get_config(Key, Settings, Default) ->
-    proplists:get_value(Key, Settings, application:get_env(ipinfo, Key, Default)).
+    proplists:get_value(Key, Settings,
+        application:get_env(ipinfo, Key, Default)).
 
 read_json(JsonFile) ->
     case file:read_file(JsonFile) of