lulezojne/flake.nix at main · haras-unicorn/lulezojne · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
{
  description = "Image to ANSI color converter heavily inspired by lule";

  inputs = {
    nixpkgs.url = "nixpkgs/nixpkgs-unstable";
    utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, utils }: {
    nixosModules.default = { pkgs, lib, config, ... }:
      with lib;
      let
        cfg = config.programs.lulezojne;
      in
      {
        options.programs.lulezojne = {
          enable = mkEnableOption (mdDoc "lulezojne");
        };

        config = mkIf cfg.enable {
          environment.systemPackages = [
            self.packages.${pkgs.system}.default
          ];
        };
      };

    homeManagerModules.default = { pkgs, lib, config, ... }:
      with lib;
      let
        cfg = config.programs.lulezojne;
        tomlFormat = pkgs.formats.toml { };
      in
      {
        options.programs.lulezojne = {
          enable = mkEnableOption (mdDoc "lulezojne");

          config =
            mkOption {
              type = tomlFormat.type;
              default = { };
              example = literalExpression ''
                {
                  plop = [
                    {
                      template = '''
                        {
                          "red": "{{ ansi.main.red }}"
                        }
                      ''';
                      "in" = "~/.config/someprogram/colors.json";
                      "then" = {
                        command = "echo";
                        args = [ "Done!" ];
                      };
                    }
                  ]
                }
              '';
              description = ''
                Lulezojne configuration.
              '';
            };
        };

        config = mkIf cfg.enable
          {
            home.packages = [
              self.packages.${pkgs.system}.default
            ];

            xdg.configFile."lulezojne/config.toml" = mkIf (cfg.config != { }) {
              source = tomlFormat.generate "lulezojne-config" cfg.config;
            };
          };
      };
  } //
  utils.lib.eachDefaultSystem (system:
    let
      pkgs = import nixpkgs.outPath {
        config = { allowUnfree = true; };
        inherit system;
      };
    in
    {
      devShells.check = pkgs.mkShell {
        buildInputs = with pkgs; [
          # Nix
          nixpkgs-fmt

          # Rust
          llvmPackages.clangNoLibcxx
          rustc
          cargo
          clippy
          rustfmt

          # Misc
          nushell
          just
          nodePackages.prettier
        ];
      };

      devShells.build = pkgs.mkShell {
        buildInputs = with pkgs; [
          # Rust
          llvmPackages.clangNoLibcxx
          rustc
          cargo

          # Misc
          nushell
          just
        ];
      };

      devShells.docs = pkgs.mkShell {
        buildInputs = with pkgs; [
          # Rust
          llvmPackages.clangNoLibcxx
          rustc
          cargo

          # Misc
          nushell
          just
        ];
      };

      devShells.default = pkgs.mkShell {
        buildInputs = with pkgs; [
          # Nix
          nil
          nixpkgs-fmt

          # Rust
          llvmPackages.clangNoLibcxx
          llvmPackages.lldb
          rustc
          cargo
          clippy
          rustfmt
          rust-analyzer
          cargo-edit

          # Misc
          simple-http-server
          nushell
          just
          nodePackages.prettier
          nodePackages.yaml-language-server
          nodePackages.vscode-json-languageserver
          marksman
          taplo
        ];

        RUST_BACKTRACE = 1;
      };

      packages.default = pkgs.rustPlatform.buildRustPackage {
        pname = "lulezojne";
        version = "0.1.0";
        src = self;
        cargoHash = "sha256-sfLYXChF3ErhGuB9+AyhAbSLtFmN05RFOc/EIcWSGXQ=";
        meta = {
          description = "Image to ANSI color converter heavily inspired by lule";
          homepage = "https://github.com/haras-unicorn/lulezojne";
          license = pkgs.lib.licenses.mit;
        };
      };
    }
  );
}