infra/job_queue.tf at main · globalbibletools/infra · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
resource "aws_ecr_repository" "job_worker" {
  name = "globalbibletools-job-worker"
}
data "aws_ecr_lifecycle_policy_document" "job_worker" {
  rule {
    priority    = 1
    description = "Removes all but the last three created images"

    selection {
      tag_status   = "any"
      count_type   = "imageCountMoreThan"
      count_number = 3
    }

    action {
      type = "expire"
    }
  }
}
resource "aws_ecr_lifecycle_policy" "job_worker" {
  repository = aws_ecr_repository.job_worker.name
  policy     = data.aws_ecr_lifecycle_policy_document.job_worker.json
}
data "aws_ecr_image" "job_worker_latest" {
  repository_name = aws_ecr_repository.job_worker.name
  image_tag       = "latest"
}

resource "aws_cloudwatch_log_group" "job_worker_lambda" {
  name = "/aws/lambda/job_worker"
}

resource "aws_iam_role" "job_worker_lambda" {
  name               = "job_worker_lambda_role"
  assume_role_policy = data.aws_iam_policy_document.lambda_assume_role.json
  path               = "/service-role/"
}
data "aws_iam_policy_document" "job_worker_lambda_role" {
  statement {
    effect    = "Allow"
    actions   = ["logs:CreateLogGroup"]
    resources = ["arn:aws:logs:us-east-1:${data.aws_caller_identity.current.account_id}:*"]
  }
  statement {
    effect    = "Allow"
    actions   = ["logs:CreateLogStream", "logs:PutLogEvents"]
    resources = ["${aws_cloudwatch_log_group.job_worker_lambda.arn}:*"]
  }
}
resource "aws_iam_policy" "job_worker_lambda_role" {
  name   = "AWSLambdaBasicExecutionRole-job-worker"
  policy = data.aws_iam_policy_document.job_worker_lambda_role.json
  path   = "/service-role/"
}
resource "aws_iam_role_policy_attachment" "job_worker_lambda_role" {
  role       = aws_iam_role.job_worker_lambda.name
  policy_arn = aws_iam_policy.job_worker_lambda_role.arn
}

resource "aws_sqs_queue" "jobs" {
  name                       = "jobs"
  visibility_timeout_seconds = 600
}

resource "aws_sqs_queue" "jobs_dlq" {
  name                      = "jobs_dlq"
  message_retention_seconds = 1209600 # 14 days

  redrive_allow_policy = jsonencode({
    redrivePermission = "byQueue",
    sourceQueueArns   = [aws_sqs_queue.jobs.arn]
  })
}

resource "aws_sqs_queue_redrive_policy" "jobs" {
  queue_url = aws_sqs_queue.jobs.id

  redrive_policy = jsonencode({
    deadLetterTargetArn = aws_sqs_queue.jobs_dlq.arn
    maxReceiveCount     = 1
  })
}

data "aws_iam_policy_document" "job_worker" {
  policy_id = "__default_policy_ID"

  statement {
    sid     = "__owner_statement"
    effect  = "Allow"
    actions = ["SQS:*"]

    principals {
      type        = "AWS"
      identifiers = ["arn:aws:iam::${data.aws_caller_identity.current.account_id}:root"]
    }
    resources = [aws_sqs_queue.jobs.arn]
  }

  statement {
    sid     = "__sender_statement"
    effect  = "Allow"
    actions = ["SQS:SendMessage"]

    principals {
      type = "AWS"
      identifiers = [
        aws_iam_role.job_worker_lambda.arn,
        aws_iam_user.app_prod.arn
      ]
    }
    resources = [aws_sqs_queue.jobs.arn]
  }

  statement {
    sid    = "__receiver_statement"
    effect = "Allow"
    actions = [
      "SQS:ChangeMessageVisibility",
      "SQS:DeleteMessage",
      "SQS:ReceiveMessage",
      "sqs:GetQueueAttributes"
    ]

    principals {
      type        = "AWS"
      identifiers = [aws_iam_role.job_worker_lambda.arn]
    }
    resources = [aws_sqs_queue.jobs.arn]
  }
}
resource "aws_sqs_queue_policy" "job_worker" {
  queue_url = aws_sqs_queue.jobs.id
  policy    = data.aws_iam_policy_document.job_worker.json
}

resource "aws_lambda_function" "job_worker" {
  function_name = "job_worker"
  role          = aws_iam_role.job_worker_lambda.arn
  package_type  = "Image"
  image_uri     = data.aws_ecr_image.job_worker_latest.image_uri
  memory_size   = 512
  timeout       = 600

  environment {
    variables = {
      DATABASE_URL                 = local.database_url
      JOB_QUEUE_URL                = aws_sqs_queue.jobs.url
      EMAIL_FROM                   = "\"Global Bible Tools\" <info@globalbibletools.com>"
      EMAIL_SERVER                 = local.smtp_url
      SERVICE_NAME                 = "job-worker"
      GOOGLE_TRANSLATE_CREDENTIALS = google_service_account_key.default.private_key
      ANALYTICS_SPREADSHEET_ID     = var.analytics_sheet_id
      BIBLE_SYSTEMS_API_KEY        = var.global_bible_systems_api_key
      GITHUB_TOKEN                 = var.github_token
      GITHUB_EXPORT_OWNER          = "globalbibletools"
      GITHUB_EXPORT_REPO           = "data"
      GITHUB_EXPORT_BRANCH         = "main"
    }
  }
}
resource "aws_lambda_event_source_mapping" "job_worker_sqs_trigger" {
  event_source_arn = aws_sqs_queue.jobs.arn
  function_name    = aws_lambda_function.job_worker.arn
  batch_size       = 1
}