flowset-bom/build.gradle at main · flowset/flowset-bom · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
/*
 * Copyright (c) Haulmont 2025. All Rights Reserved.
 * Use is subject to license terms.
 */

plugins {
    id 'java-platform'
    id 'maven-publish'
}

repositories {
    if (rootProject.hasProperty('flowsetRepoUrl')) {
        maven {
            url rootProject['flowsetRepoUrl']

            if (rootProject.hasProperty('flowsetRepoUser') && rootProject.hasProperty('flowsetRepoPassword')) {
                credentials {
                    username rootProject['flowsetRepoUser']
                    password rootProject['flowsetRepoPassword']
                }
            }
        }
        mavenCentral()
    } else {
        mavenLocal()
        maven {
            url "https://nexus.flowset.io/repository/public"
        }
        mavenCentral()
    }
}

group = 'io.flowset.bom'

javaPlatform {
    allowDependencies()
}

dependencies {
    api platform("org.springframework.cloud:spring-cloud-dependencies:2025.0.0")

    def themeVersion = version
    def uiKitVersion = version

    constraints {
        api "io.flowset.ui:flowset-theme:$themeVersion"
        api "io.flowset.ui:ui-kit:$uiKitVersion"
        api "io.flowset.ui:flowset-ui-kit-starter:$uiKitVersion"

        def camundaVersion = '7.23.0'
        api "org.camunda.community.rest:camunda-platform-7-rest-client-spring-boot:$camundaVersion"
        api "io.holunda.camunda-api:camunda-bpm-engine-api:$camundaVersion"

        api "com.fasterxml.jackson.module:jackson-module-kotlin:2.13.3"

        def mapstructVersion = '1.6.3'
        api "org.mapstruct:mapstruct:$mapstructVersion"
        api "org.mapstruct:mapstruct-processor:$mapstructVersion"

        api "org.projectlombok:lombok:1.18.36"

        api "org.vaadin.addons.componentfactory:spinner:24.1.0"

        def testcontainersVersion = '1.20.6'
        api "org.testcontainers:junit-jupiter:$testcontainersVersion"
        api "org.testcontainers:postgresql:$testcontainersVersion"
    }
}

publishing {
    if (rootProject.hasProperty('flowsetUploadUrl')) {
        repositories {
            maven {
                url = rootProject['flowsetUploadUrl']
                credentials {
                    username rootProject['flowsetUploadUser']
                    password rootProject['flowsetUploadPassword']
                }
                allowInsecureProtocol = true
            }
        }
    }

    publications {
        javaPlatformMaven(MavenPublication) {
            artifactId = 'flowset-bom'
            from components.javaPlatform
        }
    }
}