airstation-java-api/build.gradle at master · ffalcinelli/airstation-java-api · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
group 'com.github.ffalcinelli'
version '1.0-SNAPSHOT'
ext.isReleaseVersion = !version.endsWith("SNAPSHOT")

apply plugin: 'java'
apply plugin: 'jacoco'
apply plugin: 'maven'
apply plugin: 'signing'

sourceCompatibility = 1.7
targetCompatibility = 1.7

repositories {
    mavenCentral()
}

jacocoTestReport {
    reports {
        xml.enabled = true
    }
}

check.dependsOn jacocoTestReport


ext {
    okHttpVersion = "3.6.0"
}

dependencies {
    compile 'org.json:json:20160810'
    compile 'org.jsoup:jsoup:1.10.2'
    compile "com.squareup.okhttp3:okhttp:${okHttpVersion}"
    compile "com.squareup.okhttp3:okhttp-urlconnection:${okHttpVersion}"
    testCompile 'junit:junit:4.11'
    testCompile "com.squareup.okhttp3:mockwebserver:${okHttpVersion}"
}

javadoc {
    source = sourceSets.main.allJava
    destinationDir = file("${projectDir}/docs")
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives javadocJar, sourcesJar
}

signing {
    required { isReleaseVersion && gradle.taskGraph.hasTask("uploadArchives") }
    sign configurations.archives
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: System.getenv("OSSRH_USERNAME"), password: System.getenv("OSSRH_PASSWORD"))
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: System.getenv("OSSRH_USERNAME"), password: System.getenv("OSSRH_PASSWORD"))
            }

            pom.project {
                name 'airstation-java-api'
                packaging 'jar'
                // optionally artifactId can be defined here
                description 'A java client for Buffalo AirStation devices'
                url 'https://github.com/ffalcinelli/airstation-java-api'

                scm {
                    connection 'https://github.com/ffalcinelli/airstation-java-api.git'
                    developerConnection 'https://github.com/ffalcinelli/airstation-java-api.git'
                    url 'https://github.com/ffalcinelli/airstation-java-api'
                }

                licenses {
                    license {
                        name 'MIT'
                        url 'https://opensource.org/licenses/MIT'
                    }
                }

                developers {
                    developer {
                        id 'ffalcinelli'
                        name 'Fabio Falcinelli'
                        email 'fabio.falcinelli@gmail.com'
                    }
                }
            }
        }
    }
}