TradeCycle/build.gradle.kts at master · egarland/TradeCycle · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
import com.github.jengelman.gradle.plugins.shadow.ShadowPlugin

plugins {
    kotlin("jvm").version(libs.versions.jvm)
    alias(libs.plugins.shadow)
    id("java")
}

group = "net.cutecraft"
version = "1.5.0"

repositories { mavenCentral() }

val stdlib: String = libs.stdlib.get().toString()
subprojects {
    version = rootProject.version
    apply {
        apply(plugin = "org.jetbrains.kotlin.jvm")
        plugin<JavaPlugin>()
        plugin<JavaLibraryPlugin>()
        plugin<ShadowPlugin>()
    }
    repositories {
        mavenCentral()
        maven(uri("https://repo.papermc.io/repository/maven-public/"))
        maven(uri("https://hub.spigotmc.org/nexus/content/repositories/snapshots"))
    }
    kotlin {
        jvmToolchain(21)
    }
    if (project.name == "core") {
        return@subprojects
    }
    tasks {
        jar { enabled = false }
        build { dependsOn(shadowJar) }
        shadowJar {
            archiveBaseName.set(rootProject.name)
            archiveVersion.set(project.version.toString())
            archiveClassifier.set(project.name)
            destinationDirectory.set(rootProject.layout.buildDirectory.dir("libs"))
            relocate("kotlin", "net.cutecraft.libs.kotlin")
            minimize()
        }
    }
    dependencies {
        implementation(project(":core"))
        implementation(stdlib)
    }
}

tasks.jar { enabled = false }