iroha-java/build.gradle at master · dolgopolovwork/iroha-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
plugins {
    id 'com.adarshr.test-logger' version '1.6.0'
}

allprojects {
    group 'jp.co.soramitsu'
    version = "1.0"
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'groovy'
    apply plugin: 'idea'
    apply plugin: 'jacoco'
    apply plugin: 'maven'

    sourceCompatibility = 1.8 // java 8
    targetCompatibility = 1.8

    task sourcesJar(type: Jar, dependsOn: classes) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }

    task javadocJar(type: Jar, dependsOn: javadoc) {
        classifier = 'javadoc'
        from javadoc.destinationDir
    }

    artifacts {
        archives sourcesJar
        archives javadocJar
    }

    final def rootReportDir = "${buildDir}/reports/}"

    jacoco {
        toolVersion = "0.8.2"
        reportsDir = file(rootReportDir)
    }

    jacocoTestReport {
        executionData fileTree(project.rootDir.absolutePath).include("**/build/jacoco/*.exec")

        reports {
            xml.enabled true
            xml.destination file("${rootReportDir}/coverage.xml")
            csv.enabled false
            html.enabled false
            html.destination file("${rootReportDir}/html")
        }

        dependsOn(test)
    }

    test {
        testlogger {
            theme 'standard'
            showExceptions true
            slowThreshold 2000
            showSummary true
            showPassed true
            showSkipped true
            showFailed true
            showStandardStreams true
            showPassedStandardStreams false
            showSkippedStandardStreams false
            showFailedStandardStreams true
        }
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = '4.10'
}