excel-utils/build.gradle at master · dami325/excel-utils · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
import com.vanniktech.maven.publish.SonatypeHost
import com.vanniktech.maven.publish.JavaLibrary
import com.vanniktech.maven.publish.JavadocJar

plugins {
//    id 'io.spring.dependency-management' version '1.0.11.RELEASE'
    id 'java'
    id "com.vanniktech.maven.publish" version "0.28.0"
    id 'signing' // GPG 서명을 위한 플러그인
}

// Maven 그룹 및 버전 설정
group = 'io.github.dami325'
version = '0.0.5'

repositories {
    mavenCentral()
}

tasks.withType(Javadoc) {
    options {
        encoding 'UTF-8'
    }
}

signing {
//    useGpgCmd()
    sign publishing.publications
}

// Maven Publishing 블록 설정
mavenPublishing {
//    configure(new JavaLibrary(new JavadocJar.Empty(), true)) 필요시 추가
    signAllPublications() //자바 9 버전 이상이라면 useGpgCmd()를 이용하여 서명을 진행하면 됨
    publishToMavenCentral(SonatypeHost.CENTRAL_PORTAL)

    coordinates("io.github.dami325", "excel-utils", "0.0.5") // 네임 스페이스, 라이브러리 이름, 버전 순서로 작성
    // POM 설정
    pom {
        /**
         name = '[라이브러리 이름]'
         description = '[라이브러리 설명]'
         url = '[오픈소스 Repository Url]'
         */
        name = 'excel-utils'
        description = 'SpringBoot Excel Download Library'
        url = 'https://github.com/dami325/excel-utils'

        // 라이선스 정보
        licenses {
            license {
                name = 'Apache License'
                url = 'https://github.com/dami325/excel-utils/blob/master/LICENSE'
            }
        }

        // 개발자 정보
        developers {
            developer {
                id = 'dami325'
                name = 'Judalm Park'
                email = 'wnekfa1004@naver.com'
            }
            // 다른 개발자 정보...
        }

        /**
         connection = 'scm:git:github.com/[Github 사용자명]/[오픈소스 Repository 이름].git'
         developerConnection = 'scm:git:ssh://github.com/[Github 사용자명]/[오픈소스 Repository 이름].git'
         url = 'https://github.com/[Github 사용자명]/[오픈소스 Repository 이름]/tree/[배포 브랜치명]'
         */
        scm {
            connection = 'scm:git:github.com/dami325/excel-utils.git'
            developerConnection = 'scm:git:ssh://github.com:dami325/excel-utils.git'
            url = 'https://github.com/dami325/excel-utils/tree/master'
        }
    }
}

dependencies {
    // https://mvnrepository.com/artifact/org.springframework.boot/spring-boot-starter-web
    implementation group: 'org.springframework.boot', name: 'spring-boot-starter-web', version: '3.0.0'

    implementation 'org.apache.poi:poi-ooxml:5.2.3'
}