build.gradle

plugins {
	// Root에서는 기본 플러그인 버전만 명시하고 적용(apply)은 하지 않습니다.
	id 'java'
	id 'org.springframework.boot' version '3.5.9' apply false
	id 'io.spring.dependency-management' version '1.1.7' apply false
}

allprojects {
	group = 'personal.yejin'
	version = '0.0.1-SNAPSHOT'
	
	repositories {
		mavenCentral()
	}
}

subprojects {
	apply plugin: 'java'
	apply plugin: 'io.spring.dependency-management'

	// 모든 하위 모듈이 Spring Boot의 의존성 버전을 따르도록 설정
	dependencyManagement {
		imports {
			mavenBom org.springframework.boot.gradle.plugin.SpringBootPlugin.BOM_COORDINATES
		}
	}

	java {
		toolchain {
			languageVersion = JavaLanguageVersion.of(21)
		}
	}

	configurations {
		compileOnly {
			extendsFrom annotationProcessor
		}
	}

	dependencies {
		// 모든 하위 프로젝트에서 롬복 및 기본 테스트 의존성 사용
		compileOnly 'org.projectlombok:lombok'
		annotationProcessor 'org.projectlombok:lombok'
		testCompileOnly 'org.projectlombok:lombok'
		testAnnotationProcessor 'org.projectlombok:lombok'

		testImplementation 'org.springframework.boot:spring-boot-starter-test'
		testImplementation 'io.projectreactor:reactor-test'
		testImplementation 'org.mockito:mockito-core:5.5.0'
	}

	tasks.named('test') {
		useJUnitPlatform()
	}
}