nixpkgs/flake.nix at master · d4ilyrun/nixpkgs · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
{
  description = "My system config.";

  inputs = {
    nixpkgs = {
      type = "github";
      owner = "NixOs";
      repo = "nixpkgs";
      ref = "master";
    };

    home-manager = {
      type = "github";
      owner = "nix-community";
      repo = "home-manager";
      ref = "master";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nur = {
      type = "github";
      owner = "nix-community";
      repo = "NUR";
      ref = "master";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # OVERLAYS
    neovim.url = "github:nix-community/neovim-nightly-overlay";
    discord.url = "github:InternetUnexplorer/discord-overlay";
    spicetify-nix.url = "github:the-argus/spicetify-nix";
  };

  outputs = { self, nixpkgs, home-manager, ... } @ inputs:
    let
      system = "x86_64-linux";
      username = "leo"; # TODO: user module

      overlays = import ./pkgs/overlays;

      lib = nixpkgs.lib;
      pkgs = import nixpkgs {
        inherit system;
        config.allowUnfree = true;
        config.outPath = nixpkgs.outPath;
        overlays = with inputs; [
          neovim.overlay
          discord.overlay
          nur.overlay
          (self: super: {
            spicePkgs = spicetify-nix.packages."${system}".default;
          })
        ] ++ overlays;
      };

      myModules = [ ./pkgs/modules ./themes ];

      homeConfig = imports: home-manager.lib.homeManagerConfiguration {
        inherit pkgs;
        modules = imports ++ myModules;
        extraSpecialArgs = {
          inherit (inputs) spicetify-nix nixpkgs;
          lib = nixpkgs.lib.extend (final: prev:
            prev // home-manager.lib // (import ./pkgs/lib {
              inherit pkgs;
              inherit (pkgs) stdenv;
              lib = prev;
            })
          );
        };
      };
    in
    {
      nixosConfigurations =
        let
          systemConfig = modules: lib.nixosSystem { inherit system modules pkgs; };
        in
        {
          desktop = systemConfig [ ./config/desktop/configuration.nix ];
          laptop = systemConfig [ ./config/laptop/configuration.nix ];
          verna = systemConfig [ ./config/verna/configuration.nix ];
        };

      apps = pkgs;

      homeConfigurations =
        {
          desktop = homeConfig [ ./user/leo.nix ./config/desktop ];
          laptop = homeConfig [ ./user/leo.nix ./config/laptop ];
          verna = homeConfig [ ./user/leo.nix ./config/verna ];

          empty = homeConfig [ ];

          "${username}" = self.homeConfigurations.empty;
        };

      checks."${system}" =
        let
          checkConfigModule = {
            dotfiles.repository = "${./.}";
          };

          checkConfig = modules:
            (homeConfig (modules ++ [ ./user/leo.nix checkConfigModule ])).activationPackage
          ;
        in
        {
          desktop = checkConfig [ ./config/desktop ];
          laptop = checkConfig [ ./config/laptop ];
        };

      devShells."${system}" = {
        default = pkgs.mkShell {
          name = "dotfiles";
          buildInputs = [
            pkgs.stylua
          ];
        };
      };
    };
}