From c447e3125146e7e2cd01949a4eaaff91c9720ccf Mon Sep 17 00:00:00 2001
From: Excellencedev <ademiluyisuccessandexcellence@gmail.com>
Date: Tue, 16 Dec 2025 19:46:35 +0100
Subject: [PATCH 1/2] Add Oracle OCI-VM template

---
 .icons/oracle.svg                             |   1 +
 .../Excellencedev/templates/oci-vm/README.md  |  58 ++++
 .../oci-vm/cloud-init/cloud-config.yaml.tftpl |  56 +++
 .../Excellencedev/templates/oci-vm/main.tf    | 324 ++++++++++++++++++
 4 files changed, 439 insertions(+)
 create mode 100644 .icons/oracle.svg
 create mode 100644 registry/Excellencedev/templates/oci-vm/README.md
 create mode 100644 registry/Excellencedev/templates/oci-vm/cloud-init/cloud-config.yaml.tftpl
 create mode 100644 registry/Excellencedev/templates/oci-vm/main.tf

diff --git a/.icons/oracle.svg b/.icons/oracle.svg
new file mode 100644
index 000000000..0981dfcff
--- /dev/null
+++ b/.icons/oracle.svg
@@ -0,0 +1 @@
+<svg xmlns='http://www.w3.org/2000/svg' viewBox='0 0 231 30' preserveAspectRatio='xMinYMid'><path d='M99.61,19.52h15.24l-8.05-13L92,30H85.27l18-28.17a4.29,4.29,0,0,1,7-.05L128.32,30h-6.73l-3.17-5.25H103l-3.36-5.23m69.93,5.23V0.28h-5.72V27.16a2.76,2.76,0,0,0,.85,2,2.89,2.89,0,0,0,2.08.87h26l3.39-5.25H169.54M75,20.38A10,10,0,0,0,75,.28H50V30h5.71V5.54H74.65a4.81,4.81,0,0,1,0,9.62H58.54L75.6,30h8.29L72.43,20.38H75M14.88,30H32.15a14.86,14.86,0,0,0,0-29.71H14.88a14.86,14.86,0,1,0,0,29.71m16.88-5.23H15.26a9.62,9.62,0,0,1,0-19.23h16.5a9.62,9.62,0,1,1,0,19.23M140.25,30h17.63l3.34-5.23H140.64a9.62,9.62,0,1,1,0-19.23h16.75l3.38-5.25H140.25a14.86,14.86,0,1,0,0,29.71m69.87-5.23a9.62,9.62,0,0,1-9.26-7h24.42l3.36-5.24H200.86a9.61,9.61,0,0,1,9.26-7h16.76l3.35-5.25h-20.5a14.86,14.86,0,0,0,0,29.71h17.63l3.35-5.23h-20.6' transform='translate(-0.02 0)' style='fill:#C74634'/></svg>
\ No newline at end of file
diff --git a/registry/Excellencedev/templates/oci-vm/README.md b/registry/Excellencedev/templates/oci-vm/README.md
new file mode 100644
index 000000000..b7bbf2f8d
--- /dev/null
+++ b/registry/Excellencedev/templates/oci-vm/README.md
@@ -0,0 +1,58 @@
+---
+display_name: Oracle Cloud VM (Linux)
+description: Provision Oracle Cloud Infrastructure (OCI) instances as Coder workspaces
+icon: ../../../../.icons/oracle.svg
+verified: false
+tags: [vm, linux, oracle, oci]
+---
+
+# Remote Development on Oracle Cloud Infrastructure (OCI)
+
+Provision OCI virtual machines as [Coder workspaces](https://coder.com/docs/workspaces) using this Terraform template.
+
+## Prerequisites
+
+To deploy Coder workspaces on Oracle Cloud, you’ll need the following:
+
+### OCI Resources
+
+Before deploying, ensure your Oracle Cloud tenancy has:
+
+- A **VCN (Virtual Cloud Network)** already created
+- At least one **subnet** within that VCN (can be public or private)
+- An **Internet Gateway** attached to the VCN
+- A **Route Table** that routes `0.0.0.0/0` traffic to the Internet Gateway
+
+> [!NOTE]
+> This template **does not create networking resources** (VCN, subnet, gateway, etc.).  
+> You must reference an existing subnet using its **OCID** via the `subnet_id` variable.
+
+### OCI Authentication
+
+You’ll also need the following credentials:
+
+- **Tenancy OCID**
+- **User OCID**
+- **Fingerprint**
+- **Private Key**
+- **Compartment OCID**(Optional) default to Tenancy OCID if not defined
+- **Subnet OCID**
+
+[OCI Documentation](https://docs.oracle.com/en-us/iaas/Content/dev/terraform/configuring.htm#api-key-auth)
+
+---
+
+## Example `.tfvars` File
+
+```hcl
+tenancy_ocid     = "ocid1.tenancy.oc1..xxxx"
+user_ocid        = "ocid1.user.oc1..xxxx"
+fingerprint      = "aa:bb:cc:dd:ee:ff"
+subnet_id        = "ocid1.subnet.oc1.eu-marseille-1.aaaaaaaaxxx"
+region           = "eu-marseille-1"
+private_key = <<EOT
+-----BEGIN PRIVATE KEY-----
+MIIEvQIBADANBgkqhkiG9w0BAQEFAASC...
+-----END PRIVATE KEY-----
+EOT
+```
\ No newline at end of file
diff --git a/registry/Excellencedev/templates/oci-vm/cloud-init/cloud-config.yaml.tftpl b/registry/Excellencedev/templates/oci-vm/cloud-init/cloud-config.yaml.tftpl
new file mode 100644
index 000000000..1ab0587fe
--- /dev/null
+++ b/registry/Excellencedev/templates/oci-vm/cloud-init/cloud-config.yaml.tftpl
@@ -0,0 +1,56 @@
+#cloud-config
+hostname: ${hostname}
+users:
+  - name: ${username}
+    sudo: ["ALL=(ALL) NOPASSWD:ALL"]
+    groups: sudo
+    shell: /bin/bash
+packages:
+  - git
+  - curl
+  - wget
+  - unzip
+disk_setup:
+  /dev/sdb:
+    table_type: 'gpt'
+    layout: true
+    overwrite: false
+fs_setup:
+  - label: ${home_volume_label}
+    filesystem: ext4
+    device: /dev/sdb
+    partition: auto
+mounts:
+  - ["/dev/sdb", "/home/${username}", "ext4", "defaults", "0", "2"]
+write_files:
+  - path: /opt/coder/init
+    permissions: "0755"
+    encoding: b64
+    content: ${init_script}
+  - path: /etc/systemd/system/coder-agent.service
+    permissions: "0644"
+    content: |
+      [Unit]
+      Description=Coder Agent
+      After=network-online.target
+      Wants=network-online.target
+
+      [Service]
+      User=${username}
+      ExecStart=/opt/coder/init
+      Environment=CODER_AGENT_TOKEN=${coder_agent_token}
+      Restart=always
+      RestartSec=10
+      TimeoutStopSec=90
+      KillMode=process
+
+      OOMScoreAdjust=-1000
+      SyslogIdentifier=coder-agent
+
+      [Install]
+      WantedBy=multi-user.target
+runcmd:
+  - mkdir -p /home/${username}
+  - chown ${username}:${username} /home/${username}
+  - systemctl enable coder-agent
+  - systemctl start coder-agent
\ No newline at end of file
diff --git a/registry/Excellencedev/templates/oci-vm/main.tf b/registry/Excellencedev/templates/oci-vm/main.tf
new file mode 100644
index 000000000..752b81b9d
--- /dev/null
+++ b/registry/Excellencedev/templates/oci-vm/main.tf
@@ -0,0 +1,324 @@
+terraform {
+  required_providers {
+    coder = {
+      source = "coder/coder"
+    }
+    oci = {
+      source = "oracle/oci"
+    }
+  }
+}
+
+variable "tenancy_ocid" {
+  description = "Tenancy OCID"
+  type        = string
+  default     = ""
+}
+
+variable "compartment_ocid" {
+  description = "Compartment OCID"
+  type        = string
+  default     = ""
+}
+
+variable "user_ocid" {
+  description = "User OCID"
+  type        = string
+  default     = ""
+}
+
+variable "fingerprint" {
+  description = "fingerprint"
+  type        = string
+  default     = ""
+}
+
+variable "private_key" {
+  description = "Private Key File"
+  type        = string
+  default     = ""
+}
+
+variable "subnet_id" {
+  description = "Subnet OCID"
+  type        = string
+  default     = ""
+}
+
+variable "ssh_public_key" {
+  description = "SSH public key for debugging access"
+  type        = string
+  default     = ""
+}
+
+data "coder_parameter" "region" {
+  name         = "region"
+  display_name = "Region"
+  description  = "The region to deploy the workspace in."
+  default      = "eu-marseille-1"
+  mutable      = false
+  option {
+    name  = "France South (Marseille)"
+    value = "eu-marseille-1"
+    icon  = "/emojis/1f1eb-1f1f7.png"
+  }
+  option {
+    name  = "France Central (Paris)"
+    value = "eu-paris-1"
+    icon  = "/emojis/1f1eb-1f1f7.png"
+  }
+  option {
+    name  = "UK South (London)"
+    value = "uk-london-1"
+    icon  = "/emojis/1f1ea-1f1fa.png"
+  }
+  option {
+    name  = "Germany Central (Frankfurt)"
+    value = "eu-frankfurt-1"
+    icon  = "/emojis/1f1ea-1f1fa.png"
+  }
+  option {
+    name  = "US West (Phoenix)"
+    value = "us-phoenix-1"
+    icon  = "/emojis/1f1fa-1f1f8.png"
+  }
+  option {
+    name  = "US East (Ashburn)"
+    value = "us-ashburn-1"
+    icon  = "/emojis/1f1fa-1f1f8.png"
+  }
+  option {
+    name  = "Australia Southeast (Sydney)"
+    value = "ap-sydney-1"
+    icon  = "/emojis/1f1e6-1f1fa.png"
+  }
+}
+data "coder_parameter" "instance_type" {
+  name         = "instance_type"
+  display_name = "Instance type"
+  description  = "What instance type should your workspace use?"
+  default      = "VM.Standard.E3.Flex"
+  mutable      = false
+  option {
+    name  = "VM.Standard.E3.Flex"
+    value = "VM.Standard.E3.Flex"
+  }
+}
+
+data "coder_parameter" "instance_ocpus" {
+  name         = "instance_ocpus"
+  display_name = "OCPUs"
+  description  = "Number of OCPUs (only for Flex shapes)"
+  type         = "number"
+  default      = 1
+  mutable      = true
+  option {
+    name  = "1 OCPU"
+    value = 1
+  }
+  option {
+    name  = "2 OCPUs"
+    value = 2
+  }
+  option {
+    name  = "4 OCPUs"
+    value = 4
+  }
+  option {
+    name  = "8 OCPUs"
+    value = 8
+  }
+}
+
+data "coder_parameter" "instance_memory" {
+  name         = "instance_memory"
+  display_name = "Memory (GB)"
+  description  = "Amount of RAM (only for Flex shapes). Must be >= OCPUs (min 1:1 ratio) and <= 64x OCPUs (max 1:64 ratio)"
+  type         = "number"
+  default      = 2
+  mutable      = true
+  option {
+    name  = "1 GB"
+    value = 1
+  }
+  option {
+    name  = "2 GB"
+    value = 2
+  }
+  option {
+    name  = "4 GB"
+    value = 4
+  }
+  option {
+    name  = "8 GB"
+    value = 8
+  }
+  option {
+    name  = "16 GB"
+    value = 16
+  }
+  option {
+    name  = "32 GB"
+    value = 32
+  }
+
+  validation {
+    min   = data.coder_parameter.instance_ocpus.value
+    error = "Memory must be at least equal to OCPUs (minimum 1:1 ratio)."
+  }
+
+}
+
+provider "oci" {
+  tenancy_ocid = var.tenancy_ocid
+  user_ocid    = var.user_ocid
+  fingerprint  = var.fingerprint
+  private_key  = var.private_key
+  region       = data.coder_parameter.region.value
+}
+
+
+data "coder_workspace" "me" {}
+data "coder_workspace_owner" "me" {}
+
+resource "coder_agent" "main" {
+  os   = "linux"
+  arch = "amd64"
+
+  metadata {
+    key          = "cpu"
+    display_name = "CPU Usage"
+    interval     = 5
+    timeout      = 5
+    script       = "coder stat cpu"
+  }
+  metadata {
+    key          = "memory"
+    display_name = "Memory Usage"
+    interval     = 5
+    timeout      = 5
+    script       = "coder stat mem"
+  }
+  metadata {
+    key          = "home"
+    display_name = "Home Usage"
+    interval     = 600 # every 10 minutes
+    timeout      = 30  # df can take a while on large filesystems
+    script       = "coder stat disk --path /home/${lower(data.coder_workspace_owner.me.name)}"
+  }
+}
+
+locals {
+  compartment_id    = var.compartment_ocid != "" ? var.compartment_ocid : var.tenancy_ocid
+  vm_name           = "coder-${lower(data.coder_workspace_owner.me.name)}-${lower(data.coder_workspace.me.name)}"
+  root_disk_label   = substr("${local.vm_name}-root", 0, 32)
+  home_volume_label = substr("${local.vm_name}-home", 0, 32)
+}
+
+data "oci_core_images" "ubuntu_image" {
+  compartment_id           = local.compartment_id
+  operating_system         = "Canonical Ubuntu"
+  operating_system_version = "22.04"
+  shape                    = data.coder_parameter.instance_type.value
+}
+
+data "oci_identity_availability_domains" "ads" {
+  compartment_id = local.compartment_id
+}
+
+data "coder_parameter" "home_volume_size" {
+  name         = "home_volume_size"
+  display_name = "Home Volume Size (GB)"
+  description  = "How large would you like your home volume to be (in GB)?"
+  type         = "number"
+  default      = 50
+  mutable      = true
+  order        = 3
+  option {
+    name  = "50GB"
+    value = 50
+  }
+  option {
+    name  = "60GB"
+    value = 60
+  }
+  option {
+    name  = "70GB"
+    value = 700
+  }
+
+  validation {
+    monotonic = "increasing"
+  }
+}
+
+resource "oci_core_instance" "workspace" {
+  count               = data.coder_workspace.me.start_count
+  availability_domain = data.oci_identity_availability_domains.ads.availability_domains[0].name
+  compartment_id      = local.compartment_id
+  shape               = data.coder_parameter.instance_type.value
+  dynamic "shape_config" {
+    for_each = can(regex("Flex", data.coder_parameter.instance_type.value)) ? [1] : []
+    content {
+      ocpus         = data.coder_parameter.instance_ocpus.value
+      memory_in_gbs = data.coder_parameter.instance_memory.value
+    }
+  }
+  source_details {
+    source_type = "image"
+    source_id   = data.oci_core_images.ubuntu_image.images[0].id
+  }
+  display_name = local.vm_name
+  create_vnic_details {
+    assign_public_ip = true
+    subnet_id        = var.subnet_id
+  }
+  metadata = {
+    user_data = base64encode(templatefile("cloud-init/cloud-config.yaml.tftpl", {
+      hostname          = local.vm_name
+      username          = lower(data.coder_workspace_owner.me.name)
+      home_volume_label = local.home_volume_label
+      init_script       = base64encode(coder_agent.main.init_script)
+      coder_agent_token = coder_agent.main.token
+    }))
+  }
+}
+
+resource "oci_core_volume" "home_volume" {
+  availability_domain = data.oci_identity_availability_domains.ads.availability_domains[0].name
+  compartment_id      = local.compartment_id
+  display_name        = local.home_volume_label
+  size_in_gbs         = data.coder_parameter.home_volume_size.value
+}
+
+resource "oci_core_volume_attachment" "attach_home" {
+  count           = data.coder_workspace.me.start_count
+  attachment_type = "paravirtualized"
+  compartment_id  = local.compartment_id
+  instance_id     = oci_core_instance.workspace[0].id
+  #device           = "/dev/sdb"
+  volume_id = oci_core_volume.home_volume.id
+}
+
+module "code-server" {
+  count   = data.coder_workspace.me.start_count
+  source  = "registry.coder.com/coder/code-server/coder"
+  version = "~> 1.0"
+
+  agent_id = coder_agent.main.id
+  order    = 1
+}
+
+resource "coder_metadata" "workspace-info" {
+  count       = data.coder_workspace.me.start_count
+  resource_id = oci_core_instance.workspace[0].id
+
+  item {
+    key   = "region"
+    value = data.coder_parameter.region.value
+  }
+  item {
+    key   = "type"
+    value = data.coder_parameter.instance_type.value
+  }
+}
\ No newline at end of file

From 8f86896fc839401f28d5d43dd9f599cca6aa4097 Mon Sep 17 00:00:00 2001
From: Excellencedev <ademiluyisuccessandexcellence@gmail.com>
Date: Tue, 16 Dec 2025 19:57:05 +0100
Subject: [PATCH 2/2] chore: fix formatting

---
 registry/Excellencedev/templates/oci-vm/README.md | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/registry/Excellencedev/templates/oci-vm/README.md b/registry/Excellencedev/templates/oci-vm/README.md
index b7bbf2f8d..057763f0c 100644
--- a/registry/Excellencedev/templates/oci-vm/README.md
+++ b/registry/Excellencedev/templates/oci-vm/README.md
@@ -55,4 +55,4 @@ private_key = <<EOT
 MIIEvQIBADANBgkqhkiG9w0BAQEFAASC...
 -----END PRIVATE KEY-----
 EOT
-```
\ No newline at end of file
+```