Run other recipe?

[fgblomqvist]

If I have a file like:

foo:
  echo foo

bar:
  echo bar
  foo

It will error because there is no such command as foo. Makes sense. But how can I call a recipe from another? I don't want to have to use just foo since working directory etc. isn't guaranteed.

[casey]

It isn't very pretty, but you can do:

foo:
  echo foo

bar:
  echo bar
  just --justfile {{justfile()}} foo

(-f can also be used instead of --justfile.)

This has come up a few times before, so ideally there would be a nice way to do this without such hackery.

[homeworkprod]

The && syntax only seems to work for a single recipe.

For me (just version 1.38.0), this works:

validate: && validate-this
    echo "Done."

validate-this:
    echo "Validating this."

But this does not:

validate: && validate-this && validate-that
    echo "Done."

validate-this:
    echo "Validating this."

validate-that:
    echo "Validating that."

[casey]

All recipes after && will be subsequents, so you only need one:

validate: && validate-this validate-that
    echo "Done."

[homeworkprod]

@casey thanks, that works for me!

[stevenh]

Since nothing was done until now, you can evolve this hackery by using variables:

call_recipe := just_executable() + " --justfile=" + justfile()

bar:
  @echo "test"

foo:
  {{call_recipe}} bar

But more proper solution would be fine. Mostly it might help for interacting with private recipes.

Not this doesn't work in a loop on windows due to slashes.

call_recipe := just_executable() + " --justfile=" + justfile()

single *val='default':
    @echo "val = {{val}}"

multiple *vals='first second':
    for val in {{vals}}; do \
        {{call_recipe}} single $val; \
    done

just multiple
for val in first second; do C:\Users\XXX\AppData\Local\Microsoft\WinGet\Packages\Casey.Just_Microsoft.Winget.Source_8wekyb3d8bbwe\just.exe --justfile=C:\Users\XXX\code\github.com\rocketsciencegg\ai-playgound\go-ollama-perf\Justfile $val; done
sh: line 1: C:UsersXXXAppDataLocalMicrosoftWinGetPackagesCasey.Just_Microsoft.Winget.Source_8wekyb3d8bbwejust.exe: command not found
sh: line 1: C:UsersXXXAppDataLocalMicrosoftWinGetPackagesCasey.Just_Microsoft.Winget.Source_8wekyb3d8bbwejust.exe: command not found
error: Recipe `multiple` failed on line 44 with exit code 127

[enbugger]

none of it works inside modules

[GitToby]

just for further clarification, the && separates the "pre" and "post" commands. Remember the @ symbol suppresses the printing of the command.

before1:
    @echo 1

before2 my_var="2":
    @echo {{my_var}}

after1:
    @echo a

after2 my_var="b":
    @echo {{my_var}}

cmd: before1 before2 && after1 (after2 "c")
    @echo "hello world"

prints

1
2
hello world
a
c