Couldn't match type ‘IO’ with ‘Data.Functor.Identity.Identity’

[TheOddler]

I'm getting the following error in the Image example:

    • Couldn't match type ‘IO’ with ‘Data.Functor.Identity.Identity’
        arising from a functional dependency between:
          constraint ‘ArrowSchedule
                        (S.SystemT Data.Functor.Identity.Identity)
                        (Aztecs.ECS.Schedule.ScheduleT (A.AccessT IO))’
            arising from a use of ‘system’
          instance ‘ArrowSchedule (S.SystemT m) (Schedule m)’
            at <no location info>
    • In the first argument of ‘(>>>)’, namely ‘system IMG.setup’
      In the second argument of ‘(>>>)’, namely
        ‘system IMG.setup
           >>>
             system setup
               >>>
                 forever_
                   (IMG.load >>> SDL.update >>> system IMG.draw >>> SDL.draw)’
      In the expression:
        SDL.setup
          >>>
            system IMG.setup
              >>>
                system setup
                  >>>
                    forever_ (IMG.load >>> SDL.update >>> system IMG.draw >>> SDL.draw)

I was getting this in the Window example, but was able to fix it by changing the type of setup to setup :: S.SystemT IO () ().

However, in the Image example it's using the IMG.setup system which comes from Aztecs.SDL.Image so I cannot change that. Seems I need to be able to map SystemT Identity () () to SystemT IO () () somehow, but doesn't seem to be some kind of lift function?

I'm unfamiliar with arrows, and relatively new to monad transformers, so I might be missing something obvious?

[TheOddler]

Wrote my own map functions and it compiles now, but then I'm getting the following runtime error:

my-project: TODO
CallStack (from HasCallStack):
  error, called at src/Aztecs/ECS/System/Reader/Class.hs:25:18 in aztecs-0.8.0-e0cac2413cff1e8d248604026dc9cd8251b173b831816cf8fc4966ee06aa3406:Aztecs.ECS.System.Reader.Class

My full code is:

{-# LANGUAGE Arrows #-}

module Game where

import Aztecs
import Aztecs.ECS.Access qualified as A
import Aztecs.ECS.System qualified as S
import Aztecs.ECS.System.Dynamic qualified as D
import Aztecs.SDL qualified as SDL
import Aztecs.SDL.Image (Image (..))
import Aztecs.SDL.Image qualified as IMG
import Control.Arrow ((>>>))
import Control.Monad.Trans.State.Strict (mapStateT)
import Data.Functor.Identity (Identity, runIdentity)
import SDL (V2 (..))

setup :: System () ()
setup = proc () -> do
  texture <- load $ asset "assets/example.png" () -< ()
  S.queue
    ( \texture -> do
        A.spawn_ $ bundle Window {windowTitle = "Aztecs"}
        A.spawn_ $
          bundle Camera {cameraViewport = V2 1000 500, cameraScale = 5}
            <> bundle transform2d
        A.spawn_ $
          bundle Image {imageTexture = texture}
            <> bundle transform2d {transformTranslation = V2 10 10}
    )
    -<
      texture

mapS :: S.SystemT Identity i o -> S.SystemT IO i o
mapS systemT = S.System $ \components ->
  let (dynamicSystemT, readsWrites, newComponents) = S.runSystem systemT components
   in (mapD dynamicSystemT, readsWrites, newComponents)

mapD :: D.DynamicSystemT Identity i o -> D.DynamicSystemT IO i o
mapD dynT = D.DynamicSystem $ \entities i ->
  let (o, view, accessT, dynamicSystemT) = D.runSystemDyn dynT entities i
   in (o, view, mapA accessT, mapD dynamicSystemT)

mapA :: A.AccessT Identity a -> A.AccessT IO a
mapA accessT = A.AccessT . mapStateT (pure . runIdentity) $ A.unAccessT accessT

app :: Schedule IO () ()
app =
  SDL.setup
    >>> system (mapS IMG.setup)
    >>> system (mapS setup)
    >>> forever_
      ( IMG.load
          >>> SDL.update
          >>> system (mapS IMG.draw)
          >>> SDL.draw
      )

main :: IO ()
main = runSchedule_ app

[TheOddler]

Looked at the code, and seems this was updated 2 days ago, but version 0.8.0 doesn't have that code yet. So I might just wait for version 0.9.0 and have another go.

[matthunz]

Sorry for the late reply! The experience should be much smoother in v0.10 with better error messages (including the call stack) and monadic systems https://hackage.haskell.org/package/aztecs

I'm still working on updating the SDL image and text packages... I'm feeling a little overwhelmed by the current scope but I'm feeling progress on tidying up the core ECS.

With the latest version, the transformers should not longer be required and you can use something like:

import Aztecs
import qualified Aztecs.ECS.Access as A
import qualified Aztecs.SDL as SDL
import Aztecs.SDL.Image (Image (..))
import qualified Aztecs.SDL.Image as IMG
import Control.Monad
import SDL (V2 (..))

setup :: AccessT IO ()
setup = do
  texture <- load $ asset "assets/example.png" ()
  A.spawn_ $ bundle Window {windowTitle = "Aztecs"}
  A.spawn_ $
    bundle Camera {cameraViewport = V2 1000 500, cameraScale = 5}
      <> bundle transform2d
  A.spawn_ $
    bundle Image {imageTexture = texture}
      <> bundle transform2d {transformTranslation = V2 10 10}

run :: AccessT IO ()
run = do
  IMG.load
  SDL.update
  join IMG.draw
  SDL.draw

app :: AccessT IO ()
app = do
  SDL.setup
  IMG.setup
  setup
  forever run

main :: IO ()
main = runAccessT_ app

[TheOddler]

Thank you! I'll try this out in the weekend. I actually caught your update today, I opened my project thinking to upgrade to 0.9, but then saw less than an hour before 0.10 was released. Very cool!

Looking forward to trying this out more, really cool project!

[matthunz]

Thanks so much!! Let me know if you wind up giving it a go 👀