Transient menu for EKG

[garyo]

Here's a transient menu I created for EKG. I'm still very new to it so not sure about any of the commands or bindings, but for the basics it seems to work for me.

(defun setup-ekg-transients () "Set up Transient menus for EKG"
       (transient-define-prefix ekg-dispatch ()
         "Top level Transient menu for EKG (Emacs Knowledge Graph)"
         [["Show"
           ("st" "Today" ekg-show-notes-for-today)
           ("slc" "Latest Captured" ekg-show-notes-latest-captured)
           ("slm" "Latest Mod" ekg-show-notes-latest-modified)
           ("sx" "Trash" ekg-show-notes-in-trash)
           ("sd" "Drafts" ekg-show-notes-in-drafts)
           "Find Tags"
           ("tt" "Tag" ekg-show-notes-with-tag)
           ("taa" "All Tags" ekg-show-notes-with-all-tags)
           ("ta?" "Any Tag" ekg-show-notes-with-any-tags)
           ]
          ["Capture"
           ("cc" "New Note" ekg-capture)
           ("cu" "...from URL" ekg-capture-url)
           ("cb" "...from current buffer" ekg-capture-file)
           ]
          ["Query" :if (lambda () (or (featurep 'ekg-llm) (featurep 'ekg-embedding)))
           ("qt" "for terms" ekg-embedding-search :if (lambda () (featurep 'ekg-embedding)))
           ("qb" "similar to current buffer" ekg-embedding-show-similar-to-current-buffer :if (lambda () (featurep 'ekg-embedding)))
           ("qR" "Regenerate embeddings" ekg-embedding-generate-all :if (lambda () (featurep 'ekg-embedding)))
           "AI"
           ("aq" "AI query, all notes" ekg-llm-query-with-notes :if (lambda () (featurep 'ekg-llm)))
           ]
          ["Misc"
           ("gr" "Global rename tag" ekg-global-rename-tag)
           ("e" "This note ..." ekg-notes-dispatch :if-mode ekg-notes-mode)
           ("Q" "Quit this menu" transient-quit-one)
           ]
          ])

       (global-set-key (kbd "<f6>") 'ekg-dispatch)
        ; or you might prefer a binding like this one       
        ; (global-set-key (kbd "C-c e") 'ekg-dispatch)

       (transient-define-prefix ekg-notes-dispatch ()
         "Notes buffer Transient menu for EKG (Emacs Knowledge Graph)"
         [["Show Notes"
           ("sa" "with any of this note's tags" ekg-notes-any-note-tags)
           ("sA" "with any of these notes' tags" ekg-notes-any-tags)
           ("st" "select tag" ekg-notes-tag)
           ("ss" "search for similar" ekg-embedding-show-similar :if (lambda () (featurep 'ekg-embedding)))
           ]
          ["AI"
           ("aa" "AI send & append" ekg-llm-send-and-append-note :if (lambda () (featurep 'ekg-llm)))
           ("ar" "AI send & replace" ekg-llm-send-and-replace-note :if (lambda () (featurep 'ekg-llm)))
           ]
          ["Manage"
           ("c" "create" ekg-notes-create)
           ("d" "delete" ekg-notes-delete)
           ("g" "refresh" ekg-notes-refresh)
           ("k" "kill (hide) note" ekg-notes-kill)
           ("o" "open/edit" ekg-notes-open)
           ("m" "Change mode of current note" ekg-change-mode)
           ]
          ["Browse"
           ("b" "browse resource" ekg-notes-browse)
           ("u" "Browse to URL" ekg-browse-url)
           ("B" "select & browse" ekg-notes-select-and-browse-url)
           ]
          ["Global"
           ("g" "global ekg commands..." ekg-dispatch)
           ("q" "quit this menu" transient-quit-one)
           ("Q" "quit EKG" kill-buffer-and-window)
           ]
          ])
       (define-key ekg-notes-mode-map (kbd "e") 'ekg-notes-dispatch) ; can you think of a better binding for notes-mode?
       (define-key ekg-notes-mode-map (kbd "?") 'ekg-notes-dispatch) ; help when I'm confused
       (define-key ekg-notes-mode-map (kbd "q") 'kill-buffer-and-window) ; I prefer this behavior
       )

Invoke this after ekg is loaded (e.g. in the :config section of use-package). You can see I set up ? in the notes mode to bring up a notes-related transient menu, and the main one (which I bind to C-c e and <f6>) has what I took to be the main global ekg commands.

Here's what the main one looks like for me:

[garyo]

In #99, @ahyatt said "Be aware that you are mixing commands which are done on notes only, with global commands." If anyone can tell me where that mixing is taking place, I'll be happy to update this menu appropriately. There were some commands (like ekg-browse-url) where I didn't know what it really did so I just added it :-).
Anyone who knows ekg better than me, please feel free to suggest improvements.

[garyo]

Thanks, @qingshuizheng ! I've updated the menu definition and screenshot now per your recommendations.

[qingshuizheng]

@garyo It looks good! Except that you forgot to remove this line in ekg-dispatch:

("ct" "...with tags from buffer" ekg-notes-create)

And there's a typo: the second one should be ekg-notes-dispatch:

(global-set-key (kbd "<f6>") 'ekg-dispatch)
(global-set-key (kbd "C-c e") 'ekg-dispatch) ; <-- ekg-notes-dispatch

[garyo]

You are right in both cases. I'll fix it.

As for the keys, yes, I have the main one bound twice until I figure out which one I like better (on my Mac, function keys take a modifier, sigh...). I'll remove one from the published version. Key bindings are so personal!

[qingshuizheng]

Key bindings are so personal!

True. Actually I personally keep a version of transient menu locally, but with several commands of my own, and very opinionated.

Transient itself is more like a delicate machine, that is hard to touch for most users. It does provide ways to replace/append commands within, but there's a learning curve there. I think such a sample code could be included in the Wiki, to serve as a starting point.

We could have a Wiki section, right? @ahyatt :-)

[ahyatt]

Yeah! I created the wiki home page, and I think you can try to just create a page for this transient menu and see how it goes. I don't have a strong opinion on how you organize or call the page.