AudioDriver/CMakeLists.txt at main · Xtinc/AudioDriver · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
cmake_minimum_required(VERSION 3.10.0)
project(test_alsa VERSION 0.1.0 LANGUAGES C CXX)

# C++ standard
set(CMAKE_CXX_STANDARD 14)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(BUILD_SHARED_LIBS OFF)

# Find required libraries
set(AUDIO_DRIVER_DEP_LIBS TRUE)
set(AUDIO_DRIVER_HAVE_DBUS FALSE)
if(WIN32)
    set(PLATFORM_LIBS ksuser mfplat mfuuid wmcodecdspuuid Winmm)
else()
    find_package(PkgConfig QUIET)
    pkg_check_modules(ALSA QUIET alsa)
    pkg_check_modules(UDEV QUIET libudev)
    pkg_check_modules(DBUS QUIET dbus-1)

    set(PLATFORM_LIBS pthread)

    if(ALSA_FOUND AND UDEV_FOUND)
        list(APPEND PLATFORM_LIBS ${ALSA_LIBRARIES} ${UDEV_LIBRARIES})
    else()
        set(AUDIO_DRIVER_DEP_LIBS FALSE)
        message(STATUS "AudioDriver: ALSA or UDEV not found, skipping Linux build")
    endif()

    if(DBUS_FOUND)
        set(AUDIO_DRIVER_HAVE_DBUS TRUE)
        list(APPEND PLATFORM_LIBS ${DBUS_LIBRARIES})
    else()
        message(STATUS "AudioDriver: DBUS not found, building without DBUS support")
    endif()
endif()

# Only proceed with build if libraries are available
if(AUDIO_DRIVER_DEP_LIBS)
    # asio
    add_library(asio INTERFACE)
    target_include_directories(asio INTERFACE asio-1.30.2/include)
    target_compile_definitions(asio INTERFACE $<$<PLATFORM_ID:Windows>:_WIN32_WINNT=0x0601>)

    # opus - build as OBJECT library to merge into bettyaudio
    set(OPUS_BUILD_SHARED_LIBRARY OFF CACHE BOOL "" FORCE)
    set(OPUS_BUILD_TESTING OFF CACHE BOOL "" FORCE)
    add_subdirectory(opus-1.5.2)
    file(GLOB SOURCES CONFIGURE_DEPENDS source/*.cpp)
    # Main library - include opus objects directly
    add_library(bettyaudio ${SOURCES} $<TARGET_OBJECTS:opus>)
    target_include_directories(bettyaudio
        PRIVATE source
        PUBLIC include
        PUBLIC $<TARGET_PROPERTY:opus,INTERFACE_INCLUDE_DIRECTORIES>
        PUBLIC $<$<NOT:$<PLATFORM_ID:Windows>>:${ALSA_INCLUDE_DIRS}>
        PUBLIC $<$<BOOL:${AUDIO_DRIVER_HAVE_DBUS}>:${DBUS_INCLUDE_DIRS}>
    )

    target_link_libraries(bettyaudio asio ${PLATFORM_LIBS})
    target_compile_definitions(bettyaudio
        PUBLIC $<$<PLATFORM_ID:Windows>:_CRT_SECURE_NO_WARNINGS>
        PUBLIC $<$<BOOL:${AUDIO_DRIVER_HAVE_DBUS}>:AUDIO_DRIVER_HAVE_DBUS>
    )

    # Compiler-specific options for bettyaudio only
    set(GNU_CLANG_WARNING_FLAGS -Wall -Wextra -Wpedantic -Wshadow)

    target_compile_options(bettyaudio PRIVATE
        $<$<OR:$<CXX_COMPILER_ID:GNU>,$<CXX_COMPILER_ID:Clang>>:${GNU_CLANG_WARNING_FLAGS}>
    )

    # Tests
    add_subdirectory(test)

    message(STATUS "AudioDriver: Build targets created successfully")
else()
    message(STATUS "AudioDriver: Skipping all targets due to missing dependencies")
endif()