build.gradle

plugins {
    id 'net.neoforged.moddev' version '2.0.107' apply false
    id 'fabric-loom' version '1.9-SNAPSHOT' apply false
    id "me.modmuss50.mod-publish-plugin" version "0.8.0" apply false
    id 'org.moddedmc.wiki.toolkit' version '0.4.1'
}

// all projects including the root project
allprojects {
    apply plugin: 'java'
    apply plugin: 'me.modmuss50.mod-publish-plugin'

    base {
        archivesName = "$mod_id-${project.name}-$minecraft_version"
    }

    java {
        withSourcesJar()
        toolchain.languageVersion = JavaLanguageVersion.of(21)
        sourceCompatibility = JavaVersion.VERSION_21
        targetCompatibility = JavaVersion.VERSION_21
    }
}

// all projects but the root project
subprojects {
    apply plugin: 'maven-publish'

    sourceSets {
        main {
            resources {
                srcDir(file("src/main/generated"))
                exclude("**/.cache")
            }
        }
    }

    repositories {
        mavenCentral()
        
        // ModMaven
        // mirrors a lot of commonly used Mavens
        maven { url = "https://modmaven.dev" }
        // CurseMaven
        // Jade, Oracle Index
        maven { url = "https://beta.cursemaven.com" }
        
        // Architectury API, REI
        maven { url = "https://maven.architectury.dev/" }
        // Athena (CTM)
        maven { url = "https://maven.teamresourceful.com/repository/maven-public/" }
        // EMI
        maven { url = 'https://maven.terraformersmc.com/' }
        // Forgified Fabric API
        maven { url = "https://maven.su5ed.dev/releases" }
        // FTB Chunks
        maven { url = "https://maven.ftb.dev/releases" }
        // GeckoLib
        maven { url = 'https://dl.cloudsmith.io/public/geckolib3/geckolib/maven/' }
        // owo-lib
        maven { url = 'https://maven.wispforest.io/releases/' }
        // Forge Config API Port
        maven { url = 'https://raw.githubusercontent.com/Fuzss/modresources/main/maven/' }
    }

    dependencies {
        // Auto Services
        compileOnly "com.google.auto.service:auto-service:$autoServiceVersion"
        annotationProcessor "com.google.auto.service:auto-service:$autoServiceVersion"
    }

    ['apiElements', 'runtimeElements', 'sourcesElements'].each { variant ->
        configurations."$variant".outgoing {
            capability("$group:${base.archivesName.get()}:$version")
            capability("$group:$mod_id-${project.name}-${minecraft_version}:$version")
            capability("$group:$mod_id:$version")
        }
        publishing.publications.configureEach {
            suppressPomMetadataWarningsFor(variant)
        }
    }

    tasks.withType(AbstractCopyTask).configureEach {
        duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    }

    // configure Maven publishing
    publishing {
        publications {
            mavenJava(MavenPublication) {
                artifactId = base.archivesName.get()
                from components.java
            }
        }
        repositories {
            maven {
                url System.getenv('local_maven_url')
            }
        }
    }
}

// only loader projects
subprojects {
    if (project.path == ":common") {
        return
    }

    configurations {
        commonJava {
            canBeResolved = true
        }
        commonResources {
            canBeResolved = true
        }
    }

    dependencies {
        compileOnly(project(':common')) {
            capabilities {
                requireCapability "$group:$mod_id"
            }
            transitive = false
        }
        commonJava project(path: ':common', configuration: 'commonJava')
        commonResources project(path: ':common', configuration: 'commonResources')
    }

    sourceSets {
        create("data") {
            compileClasspath += sourceSets.main.output
            runtimeClasspath += sourceSets.main.output
            compileClasspath += sourceSets.main.compileClasspath
            runtimeClasspath += sourceSets.main.runtimeClasspath
        }
    }

    tasks {
        processResources {
            dependsOn(configurations.commonResources)
            from(configurations.commonResources)
            
            // copy wiki folder to assets
            from("$rootDir/docs") {
                into "assets/oracle_index/books/oritech"
                exclude '.assets/item/**' // items are rendered in-game as actual item components, no need to include them here
            }
        
            inputs.property 'version', project.version
            filesMatching(['META-INF/neoforge.mods.toml', "fabric.mod.json"]) {
                expand version: version
            }
        }

        named('compileJava', JavaCompile) {
            dependsOn(configurations.commonJava)
            source(configurations.commonJava)
        }

        named('sourcesJar', Jar) {
            dependsOn(configurations.commonJava)
            from(configurations.commonJava)
            dependsOn(configurations.commonResources)
            from(configurations.commonResources)
        }
    }
}

// sinytra wiki
wiki {
    docs {
        oritech {
            // path to the folder containing metadata file (sinytra-wiki.json)
            root = file('docs')
        }
    }
}

publishMods {
    github {
        accessToken = providers.environmentVariable("GITHUB_TOKEN")
        repository = "Rearth/Oritech"
        commitish = "1.21"
        changelog = file("./CHANGELOG.MD").getText()
        type = STABLE
        tagName = "v${project.version}"

        // Allow the release to be initially created without any files.
        allowEmptyFiles = true
    }
}