Terraform-AWS-REST-API-DynamoDB-Architecture-Pattern/rest-api.tf at main · QloudX/Terraform-AWS-REST-API-DynamoDB-Architecture-Pattern · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
data "aws_region" "region" {}

locals {
  openAPI_spec = {
    "/item" : {
      post : {
        responses : {
          200 : { content : { "application/json" : { schema : {} } } }
        }
        x-amazon-apigateway-integration : {
          type : "aws"
          httpMethod : "POST"
          credentials : aws_iam_role.iam_role.arn
          responses : { default : { statusCode : "200" } }
          uri : "arn:aws:apigateway:${data.aws_region.region.name}:dynamodb:action/PutItem"
        }
      }

      get : {
        parameters : [{
          name : "id"
          in : "query"
          required : true
          schema : { type : "string" }
          }, {
          name : "table"
          in : "query"
          required : true
          schema : { type : "string" }
        }]
        responses : {
          200 : { content : { "application/json" : { schema : {} } } }
        }
        x-amazon-apigateway-integration : {
          type : "aws"
          httpMethod : "POST"
          credentials : aws_iam_role.iam_role.arn
          responses : { default : { statusCode : "200" } }
          uri : "arn:aws:apigateway:${data.aws_region.region.name}:dynamodb:action/GetItem"
          requestTemplates : {
            "application/json" : jsonencode({
              TableName : "$input.params('table')"
              Key : { id : { S : "$input.params('id')" } }
            })
          }
        }
      }

      delete : {
        parameters : [{
          name : "id"
          in : "query"
          required : true
          schema : { type : "string" }
          }, {
          name : "table"
          in : "query"
          required : true
          schema : { type : "string" }
        }]
        responses : {
          200 : { content : { "application/json" : { schema : {} } } }
        }
        x-amazon-apigateway-integration : {
          type : "aws"
          httpMethod : "POST"
          credentials : aws_iam_role.iam_role.arn
          responses : { default : { statusCode : "200" } }
          uri : "arn:aws:apigateway:${data.aws_region.region.name}:dynamodb:action/DeleteItem"
          requestTemplates : {
            "application/json" : jsonencode({
              TableName : "$input.params('table')"
              Key : { id : { S : "$input.params('id')" } }
            })
          }
        }
      }
    }
  }
}

resource "aws_api_gateway_rest_api" "rest_api" {
  name = var.api_name
  endpoint_configuration {
    types = ["REGIONAL"]
  }
  body = jsonencode({
    openapi = "3.0.1"
    paths   = local.openAPI_spec
  })
}