se-api/build.gradle.kts at main · PACK-Solutions/se-api · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
import io.gitlab.arturbosch.detekt.extensions.DetektExtension
import nl.littlerobots.vcu.plugin.resolver.VersionSelectors

plugins {
    alias(libs.plugins.kotlin.jvm) apply false
    alias(libs.plugins.kotest) apply false
    alias(libs.plugins.detekt)
    alias(libs.plugins.version.catalog.update)
    alias(libs.plugins.versions)
}

allprojects {
    repositories {
        mavenCentral()
    }
}

subprojects {
    // Apply common plugins to all subprojects
    apply(plugin = "org.jetbrains.kotlin.jvm")
    apply(plugin = "io.kotest")
    apply(plugin = "io.gitlab.arturbosch.detekt")
    apply(plugin = "version-catalog")

    // Configure Java toolchain for all JVM projects
    extensions.configure<JavaPluginExtension> {
        toolchain {
            languageVersion.set(JavaLanguageVersion.of(21))
        }
    }

    // Detekt configuration
    extensions.configure<DetektExtension> {
        config.setFrom("${rootProject.projectDir}/detekt.yml")
        buildUponDefaultConfig = true
        autoCorrect = true
    }


    // Ensure tests run on JUnit Platform (required by Kotest)
    tasks.withType<Test>().configureEach {
        useJUnitPlatform()
    }
}

// Apply internal buildSrc plugin that provides the setupCodeConventions task
apply(plugin = "com.ps.code-conventions")

versionCatalogUpdate {
    versionSelector(VersionSelectors.STABLE)
}