variables.tf

variable "owner_tag" {
  description = "Propietario de la VNet"
  type        = string

  validation {
    condition     = length(trim(var.owner_tag, " ")) > 0
    error_message = "El valor de owner_tag no puede estar vacío."
  }
}

variable "environment_tag" {
  description = "Entorno de la VNet (DEV, PRO, TES, PRE)"
  type        = string

  validation {
    condition = contains(
      ["DEV", "PRO", "TES", "PRE"],
      upper(trim(var.environment_tag, " "))
    )
    error_message = "environment_tag debe ser uno de: DEV, PRO, TES o PRE (insensible a mayúsculas)."
  }
}

variable "vnet_name" {
  description = "Nombre de la VNet"
  type        = string

  validation {
    condition     = can(regex("^vnet[a-z]{3,}tfexercise[0-9]{2}$", var.vnet_name))
    error_message = "vnet_name debe empezar por 'vnet', seguido de al menos 3 letras minúsculas, y terminar en 'tfexercise' seguido de 2 dígitos (ej: vnetoscarztfexercise01)."
  }
}

variable "vnet_address_space" {
  description = "Rango de direcciones IP para la VNet"
  type        = list(string)
}

variable "location" {
  description = "Ubicación de la VNet"
  type        = string
  default     = "West Europe"
}

variable "vnet_tags" {
  description = "Mapa de tags adicionales para la VNet"
  type        = map(string)
  default     = {}

  validation {
    condition     = var.vnet_tags != null && alltrue([for value in var.vnet_tags : length(trim(value, " ")) > 0])
    error_message = "vnet_tags no puede ser null y todos los valores deben ser cadenas no vacías."
  }
}

variable "existent_resource_group_name" {
  description = "Nombre del resource group ya existente"
  type        = string
}