From 03a1ea720bbb5abf5b95c7b917b9dd8035ace19e Mon Sep 17 00:00:00 2001
From: ngc7331 <ngc7331@outlook.com>
Date: Thu, 26 Feb 2026 17:42:17 +0800
Subject: [PATCH] chore: add nix flake for xs-env

Signed-off-by: ngc7331 <ngc7331@outlook.com>
---
 .gitignore |  3 +++
 flake.lock | 27 +++++++++++++++++++++++
 flake.nix  | 64 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 3 files changed, 94 insertions(+)
 create mode 100644 flake.lock
 create mode 100644 flake.nix

diff --git a/.gitignore b/.gitignore
index 2d679cf..aa0c883 100644
--- a/.gitignore
+++ b/.gitignore
@@ -17,3 +17,6 @@ doc/html
 *.txt
 emu/obj*
 playground/
+
+# nix build .
+result
diff --git a/flake.lock b/flake.lock
new file mode 100644
index 0000000..e683879
--- /dev/null
+++ b/flake.lock
@@ -0,0 +1,27 @@
+{
+  "nodes": {
+    "nixpkgs": {
+      "locked": {
+        "lastModified": 1771903837,
+        "narHash": "sha256-sdaqdnsQCv3iifzxwB22tUwN/fSHoN7j2myFW5EIkGk=",
+        "owner": "NixOS",
+        "repo": "nixpkgs",
+        "rev": "e764fc9a405871f1f6ca3d1394fb422e0a0c3951",
+        "type": "github"
+      },
+      "original": {
+        "owner": "NixOS",
+        "ref": "nixos-25.11",
+        "repo": "nixpkgs",
+        "type": "github"
+      }
+    },
+    "root": {
+      "inputs": {
+        "nixpkgs": "nixpkgs"
+      }
+    }
+  },
+  "root": "root",
+  "version": 7
+}
diff --git a/flake.nix b/flake.nix
new file mode 100644
index 0000000..e2d4f9a
--- /dev/null
+++ b/flake.nix
@@ -0,0 +1,64 @@
+{
+  description = "GSIM: A Fast RTL Simulator for Large-Scale Designs";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
+  };
+
+  outputs = { self, nixpkgs, ... }:
+    let
+      systems = nixpkgs.lib.systems.flakeExposed;
+      perSystem = nixpkgs.lib.genAttrs systems (system:
+        let
+          pkgs = import nixpkgs { inherit system; };
+          llvm = pkgs.llvmPackages_19;
+          gsim = llvm.stdenv.mkDerivation {
+            pname = "gsim";
+            version = "1.0.0-dev"; # FIXME?
+            src = self;
+
+            strictDeps = true;
+            enableParallelBuilding = true;
+            dontConfigure = true;
+
+            nativeBuildInputs = [
+              pkgs.flex
+              pkgs.bison
+            ];
+            buildInputs = [
+              pkgs.flex
+              pkgs.gmp
+            ];
+
+            makeFlags = [
+              # gsim defaults to /bin/bash, which is not guaranteed in NixOS
+              "SHELL=${llvm.stdenv.shell}"
+              # override default build target to avoid running tests
+              "build-gsim"
+            ];
+
+            installPhase = ''
+              runHook preInstall
+              install -Dm755 build/gsim/gsim $out/bin/gsim
+              runHook postInstall
+            '';
+
+            meta = {
+              description = "Fast RTL Simulator for Large-Scale Designs";
+              homepage = "https://github.com/OpenXiangShan/gsim";
+              platforms = pkgs.lib.platforms.linux;
+            };
+          };
+        in
+        {
+          packages = {
+            gsim = gsim;
+            default = gsim;
+          };
+        }
+      );
+    in
+    {
+      packages = nixpkgs.lib.mapAttrs (_: v: v.packages) perSystem;
+    };
+}