Lombok, Spring and Java

[muItilingualism]

Hi, I can't seem to figure out how to enable lombok support. I have JDTLS working with the following

{ nvf, ... }:

{
  imports = [ nvf.homeManagerModules.default ];

  programs.nvf = {
    enable = true;
    settings = {
      vim = {
        viAlias = true;
        vimAlias = true;

        languages = {
          java = {
            enable = true;
            lsp.enable = true;
            treesitter.enable = true;
          };
          #...
        };

        git.enable = true;

        telescope.enable = true;
        treesitter.enable = true;
        statusline.lualine.enable = true;

        #...
      };
    };
  };
}

Anyone have an example config which works?

I am also curious if there is support for Spring?

Thanks!

[NotAShelf]

I do not have much experience with Java. For Kotlin and Java, anything beyond Jetbrains IDEs seem to be on life support at best, although I am interested in supporting more use cases. I'm going to look into Lombok support (which isn't directly supported, unless it's supposed to work OOTB with JDTLS) and possibly even Spring as soon as I get the chance.

Edit: according to lspconfig documentation, lombok should be supported with jdtls. jdtls-launcher appears to be semi-recommended, but it is not packaged for Nix. Setting JDTLS_JVM_ARGS in a wrapper, or directly in your sessionVariables might be helpful for Lombok.

export JDTLS_JVM_ARGS="-javaagent:$HOME/.local/share/java/lombok.jar"

I found spring-boot.nvim for Spring Boot, which I can add as an extension for the Java language module.

[NotAShelf]

It might be that the environment var is not being properly propagated to the server binary.

Using writeShellScriptBin might be able to better handle the environment variable. Do you have an example project that uses lombok that I can use to test?

[muItilingualism]

I put this one together, there is more info in the readme :)

https://github.com/muItilingualism/lombok-example

[NotAShelf]

Thank you, I'll test as soon as I get home.

[NotAShelf]

The problem was, in fact, that the environment variable is not being properly propagated to the jdtls binary. With how Nix operates, I am not entirely surprised. The following setup allows Lombok to function properly, although I am not sure which extent. LSP hover seems to be working at least, so that is a good start.

java = let
  jdtlsCache = "$XDG_CACHE_HOME/jdtls";
in {
  enable = true;
  lsp.package = pkgs.writeShellScriptBin "start-jdtls" ''
    ${lib.getExe pkgs.jdt-language-server} \
      -configuration ${jdtlsCache}/config -data ${jdtlsCache}/workspace \
      --jvm-arg="-javaagent:${pkgs.lombok.outPath}/share/java/lombok.jar"
  '';
};

I think .outPath can also be replaced with .bin, but not a huge deal. Hope this helps.

[muItilingualism]

Thank you very much for your help. I got an access error with your exact config, however I got the following configuration to work :).

{ nvf, pkgs, lib, ... }:

{
  imports = [ nvf.homeManagerModules.default ];

  programs.nvf = {
    enable = true;
    settings = {
      vim = {
        viAlias = true;
        vimAlias = true;

        options = {
          #...
        };

        languages = {
          java = let
            jdtlsCache = "~/.cache/jdtls";
          in {
            enable = true;
            lsp.package = pkgs.writeShellScriptBin "start-jdtls" ''
              ${lib.getExe pkgs.jdt-language-server} \
                -configuration ${jdtlsCache}/config -data ${jdtlsCache}/workspace \
                --jvm-arg="-javaagent:${pkgs.lombok.outPath}/share/java/lombok.jar"
            '';
            lsp.enable = true;
            treesitter.enable = true;
          };
          #...
        };

        #...
      };
    };
  };
}