UnofficialMonumentaMod/build.gradle at master · Njol/UnofficialMonumentaMod · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
plugins {
    id 'fabric-loom' version '0.12-SNAPSHOT'
    id 'maven-publish'
    id "com.modrinth.minotaur" version "2.+"
    id "com.matthewprenger.cursegradle" version "1.+"
//    id 'java'
//    id 'com.github.johnrengelman.shadow' version '1.2.2'
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

archivesBaseName = project.archives_base_name + "-mc" + project.minecraft_version
version = project.mod_version
group = project.maven_group

dependencies {
    //to change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // Fabric API. This is technically optional, but you probably want it anyway.
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    modApi "com.terraformersmc:modmenu:3.2.3"
    modApi("me.shedaniel.cloth:cloth-config-fabric:6.2.62") {
        exclude(group: "net.fabricmc.fabric-api")
    }
    include(implementation('club.minnced:discord-rpc-release:v3.4.0'))
    include(implementation("com.github.MinnDevelopment:java-discord-rpc:v2.0.2"))

    modApi "ch.njol.minecraft:ui-framework-mc1_18:${project.ui_framework_version}"
    include "ch.njol.minecraft:ui-framework-mc1_18:${project.ui_framework_version}"
    modApi "ch.njol.minecraft:config-framework-mc1_18:${project.config_framework_version}"
    include "ch.njol.minecraft:config-framework-mc1_18:${project.config_framework_version}"
}
repositories {
    mavenLocal()
    mavenCentral()
    maven { url = "https://maven.terraformersmc.com" }
    maven { url = "https://maven.shedaniel.me/" }
    jcenter()
    maven { url = "https://jitpack.io/" }
}

processResources {
    from(sourceSets.main.resources.srcDirs) {
        include "fabric.mod.json"
        expand project.properties
        duplicatesStrategy = 'include'
    }

    from(sourceSets.main.resources.srcDirs) {
        exclude "fabric.mod.json"
        duplicatesStrategy = 'include'
    }
}

// ensure that the encoding is set to UTF-8, no matter what the system default is
// this fixes some edge cases with special characters not displaying correctly
// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
}

// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
// if it is present.
// If you remove this task, sources will not be generated.
task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = "sources"
    from sourceSets.main.allSource
}

jar {
    from "LICENSE"
}
//shadowJar {
//    dependencies {
//        include(dependency('me.shedaniel.cloth:cloth-config-fabric:.*'))
//    }
//}

// configure the maven publication
publishing {
    publications {
        mavenJava(MavenPublication) {
            // add all the jars that should be included when publishing to maven
            artifact(remapJar) {
                builtBy remapJar
            }
            artifact(sourcesJar) {
                builtBy remapSourcesJar
            }
        }
    }

    // select the repositories you want to publish to
    repositories {
        // uncomment to publish to the local maven
        // mavenLocal()
    }
}

def changeLog = '''

'''

modrinth {
    token = System.getenv("MODRINTH_TOKEN")
    projectId = "unofficial-monumenta-mod"
    versionNumber = project.mod_version
    versionType = "release"
    uploadFile = remapJar
    gameVersions = ["1.18.2"]
    loaders = ["fabric"]
    changelog = changeLog
    dependencies {
        required.project "fabric-api"
        optional.project "modmenu"
        optional.project "cloth-config"
    }
    // debugMode = true
}

curseforge {
    if (System.getenv("CURSEFORGE_TOKEN") != null) {
        apiKey = System.getenv("CURSEFORGE_TOKEN")
    }
    project {
        id = '509666'
        changelog = changeLog
        releaseType = 'release'
        addGameVersion '1.18.2'
        addGameVersion 'Fabric'

        mainArtifact(remapJar) {
            relations {
                requiredDependency "fabric-api"
                optionalDependency "modmenu"
                optionalDependency "cloth-config"
            }
        }
        options {
            // debug = true
        }
    }
}