retoday-server/build.gradle.kts at dev · Nexters/retoday-server · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
import org.jetbrains.kotlin.gradle.dsl.JvmTarget

plugins {
    alias(libs.plugins.java.library)
    alias(libs.plugins.java.test.fixtures)
    alias(libs.plugins.kotlin.jvm)
    alias(libs.plugins.kotlin.spring) apply false
    alias(libs.plugins.kotlin.lint) apply false
    alias(libs.plugins.spring.boot) apply false
    alias(libs.plugins.spring.dependency.management) apply false
}

allprojects {
    group = "com.retoday"
    version = "0.0.1"

    repositories {
        google()
        mavenCentral()
    }
}

subprojects {
    fun apply(provider: Provider<PluginDependency>) {
        apply(plugin = provider.get().pluginId)
    }

    apply(rootProject.libs.plugins.java.library)
    apply(rootProject.libs.plugins.java.test.fixtures)
    apply(rootProject.libs.plugins.kotlin.jvm)
    apply(rootProject.libs.plugins.kotlin.spring)
    apply(rootProject.libs.plugins.kotlin.lint)
    apply(rootProject.libs.plugins.spring.boot)
    apply(rootProject.libs.plugins.spring.dependency.management)

    java {
        sourceCompatibility = JavaVersion.VERSION_21
    }

    kotlin {
        compilerOptions {
            freeCompilerArgs = listOf("-Xjsr305=strict")
            jvmTarget = JvmTarget.JVM_21
        }
    }

    configurations {
        all {
            exclude("org.springframework.boot", "spring-boot-starter-logging")
        }
    }

    dependencies {
        testImplementation(rootProject.libs.bundles.test)
    }

    tasks {
        test {
            useJUnitPlatform()
            classpath += files(sourceSets.main.map { it.output })
        }
    }
}