niri/scope.nix at main · Naxdy/niri · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
{
  advisory-db,
  crane,
  fenix,
  generateSplicesForMkScope,
  makeScopeWithSplicing',
  self,
  stdenv,
}:
makeScopeWithSplicing' {
  otherSplices = generateSplicesForMkScope "niriPackages";
  extra =
    final:
    let
      mkToolchain =
        p:
        let
          fenix' = p.callPackage fenix { };

          targetMap = {
            aarch64-linux = "aarch64-unknown-linux-gnu";
            x86_64-linux = "x86_64-unknown-linux-gnu";
          };

          target-toolchain = fenix'.targets.${targetMap.${stdenv.hostPlatform.system}}.stable;

          toolchain = fenix'.stable;
        in
        fenix'.combine [
          toolchain.rustc
          toolchain.cargo
          toolchain.rust-src
          toolchain.rustfmt
          toolchain.clippy
          target-toolchain.rust-std
        ];
    in
    {
      inherit
        advisory-db
        self
        ;

      craneLib = (crane.mkLib final).overrideToolchain mkToolchain;
      rustToolchain = mkToolchain final;
      mkNiriDerivation = final.callPackage ./nix/util/niri-derivation.nix { };
    };
  f = final: {
    callPackage' = pkg: attrs: (final.callPackage pkg attrs) // { niriPackage = true; };

    niri = final.callPackage' ./nix/pkgs/niri { };
    niri-visual-tests = final.callPackage' ./nix/pkgs/niri-visual-tests { };
    niri-config = final.callPackage' ./nix/pkgs/niri-config { };
    niri-ipc = final.callPackage' ./nix/pkgs/niri-ipc { };
  };
}