build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '4.0.0'
    id 'io.spring.dependency-management' version '1.1.7'
}

group = 'xyz.ncookie'
version = '0.0.1-SNAPSHOT'
description = 'stargazer'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    // Spring
    implementation 'org.springframework.boot:spring-boot-starter-webmvc'
    implementation 'org.springframework.boot:spring-boot-starter-validation'

    developmentOnly 'org.springframework.boot:spring-boot-devtools'

    // lombok
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'

    // Spring Security & OAuth2
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'org.springframework.boot:spring-boot-starter-oauth2-client'

    // JWT
    implementation 'io.jsonwebtoken:jjwt-api:0.11.5'
    runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.11.5'
    runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.11.5'

    // DB
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.hibernate.orm:hibernate-spatial'

    implementation 'org.springframework.boot:spring-boot-starter-data-redis'

    runtimeOnly 'com.mysql:mysql-connector-j'

    // Cache
    implementation 'org.springframework.boot:spring-boot-starter-cache'
    implementation 'com.github.ben-manes.caffeine:caffeine'

    // Rate limiting
    implementation 'com.bucket4j:bucket4j_jdk17-core:8.14.0'

    // Stargazing
    implementation 'org.shredzone.commons:commons-suncalc:3.7'

    // JSON
    implementation 'com.fasterxml.jackson.core:jackson-databind'

    // Swagger / OpenAPI
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.7.0'

    // test
    testImplementation 'org.springframework.boot:spring-boot-starter-webmvc-test'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
    testImplementation 'org.springframework.boot:spring-boot-starter-data-jpa-test'
}

tasks.named('test') {
    useJUnitPlatform()
}

tasks.register('generateOpenApi') {
    doLast {
        def apiDocsUrl = "http://localhost:8080/v3/api-docs"
        def outputFile = file("${projectDir}/openapi.json")


        println "Fetching OpenAPI docs from ${apiDocsUrl}..."


        def connection = new URL(apiDocsUrl).openConnection()
        connection.setRequestProperty("Accept", "application/json")


        def json = connection.inputStream.getText("UTF-8")
        outputFile.withWriter("UTF-8") { writer ->
            writer.write(json)
        }

        println "OpenAPI JSON saved to ${outputFile.absolutePath}"
    }
}