build.gradle

import com.vanniktech.maven.publish.SonatypeHost
import com.vanniktech.maven.publish.JavaLibrary
import com.vanniktech.maven.publish.JavadocJar


buildscript {
    repositories {
        mavenLocal()
        mavenCentral()
        maven { url "https://mauro-repository.com/libs-release-local" }
        maven { url "https://plugins.gradle.org/m2/" }
        maven { url 'https://repo.gradle.org/gradle/libs-releases-local/' }
        maven { url "https://mauro-repository.com/libs-snapshot-local" }
        maven { url "https://mauro-repository.com/plugins-release-local" }
        maven { url "https://mauro-repository.com/plugins-snapshot-local" }

    }

}

plugins {
    id 'groovy'
    id 'java'
    id 'antlr'
    id 'maven-publish'
    id "com.vanniktech.maven.publish" version "0.29.0"
    id "com.github.hierynomus.license" version "0.16.1"
    id 'codenarc'
    id 'idea'
}

repositories {
    mavenLocal()
    maven {url "https://plugins.gradle.org/m2/"}
    mavenCentral()
    maven {url "https://mauro-repository.com/libs-release-local"}
    maven {url "https://mauro-repository.com/libs-snapshot-local"}
    maven {url "https://mauro-repository.com/plugins-release-local"}
}

// Define new "generation" sourceset for generating the dita library
sourceSets {
    // Source is the generation code and the antlr generated source
    generation {
        groovy.srcDirs = ['src/generation/groovy', "${project.buildDir}/generated-src/generation/antlr"]
    }
    // Add the dita generated source into the main src
    main {
        groovy.srcDirs += ["${project.buildDir}/generated-src/main/dita"]
    }
}

tasks.register('baseJar', Jar) {
    archiveBaseName.set("dita-dsl-base")
    from sourceSets.main.output
    exclude 'org/maurodata/dita/elements/langref/learningtraining/**'
    exclude 'org/maurodata/dita/elements/langref/technicalcontent/**'
}

license {
    excludes(["${project.buildTreePath}/**",
            "**/*.xml"])
    header(project.file('NOTICE'))
}

// Setup the generation sourceset configurations to extend from the existing configurations
// Note that the antlr plugin adds a new configuration which is loaded into the compileClasspath
configurations {
    generationImplementation.extendsFrom implementation
    generationRuntimeOnly.extendsFrom runtimeOnly
}

test {
    useJUnitPlatform()
}

jar{
    exclude 'logback.*', 'log4j.*'
}

// Make sure we dont stamp addtl files with our license
license {
    excludes([
        '**/dita-ot-*/*',
        '**/*.g4',
        '**/org/maurodata/dita/ebnf/parser/*',
        '**/*.properties'
    ])
}



// Customise the antlr grammer source to output to the "generation/antlr" directory
// Standard format of src dirs is "sourcesetname/codetype"
generateGrammarSource {
    outputDirectory = project.file("${project.buildDir}/generated-src/generation/antlr")
    maxHeapSize = "128m"
    arguments += ['-visitor', '-no-listener']
}

tasks.register('replaceTabsWithSpaces'){
    doLast{
        tasks.generateGrammarSource.outputDirectory.traverse(type: groovy.io.FileType.FILES, nameFilter: ~/.*\.java$/){
            it.write(it.text.replaceAll(/\t/,'    '))
        }
    }
}

// Register a new task to generate the dita source into "main/dita" directory
tasks.register('generateDitaSource', JavaExec) {
    ext.destDir = project.file('build/generated-src/main/dita')
    outputs.dir destDir

    classpath = sourceSets.generation.runtimeClasspath
    mainClass = 'org.maurodata.dita.generation.DocumentationParser'
    // arguments to pass to the application
    argsString = 'build/generated-src/main/dita'
}

java {
    withSourcesJar()
    withJavadocJar()
}

// Ensure tasks are run in the correct order
// antlr grammar -> generation source set compiled -> dita source generated -> main code compiled
tasks.generateGrammarSource.finalizedBy 'replaceTabsWithSpaces'
tasks.compileGenerationJava.dependsOn 'generateGrammarSource','replaceTabsWithSpaces'
tasks.generateDitaSource.dependsOn 'generationClasses'
tasks.compileJava.dependsOn 'generateDitaSource'
tasks.sourcesJar.dependsOn 'generateDitaSource'
tasks.licenseGeneration.dependsOn "generateGrammarSource", "generateGenerationGrammarSource", "generateDitaSource"
tasks.licenseTest.dependsOn "generateGrammarSource", "generateGenerationGrammarSource", "generateDitaSource", "generateTestGrammarSource"
tasks.licenseMain.dependsOn "generateDitaSource"


codenarc {
    configFile = rootProject.file("config/codenarc/codenarc.groovy")
    ignoreFailures = true

}

codenarcGeneration {
    compilationClasspath = sourceSets.generation.compileClasspath + sourceSets.generation.output
    // Dont bother scanning the generated code, we've cleaned up most of the issues, the ones remaining are impossible to fix due to the source they're generated from
    exclude '**/dita/elements/langref/**'
    exclude '**/parser/**'
    ignoreFailures = true
}

codenarcMain {
    compilationClasspath = sourceSets.main.compileClasspath + sourceSets.main.output
    // Dont bother scanning the generated code, we've cleaned up most of the issues, the ones remaining are impossible to fix due to the source they're generated from
    exclude '**/dita/elements/langref/**'
    exclude '**/parser/**'
    ignoreFailures = true
}



afterEvaluate {
    // Make sure intellij shows the build folder so we can see the generated code
    // And add the src/main/antlr directory (source dir for antlr plugin) to the source listing so it looks right
    idea.module{
        sourceDirs << project.file('src/main/antlr')
    }
    jar {
        manifest {
            attributes(
                "Class-Path": configurations.runtimeClasspath.collect {it.getName()}.join(' '))
        }
    }

    // Make sure groovy tasks can compile
    tasks.withType(GroovyCompile).configureEach {
        configure(groovyOptions.forkOptions) {
            memoryMaximumSize = '4g'
            jvmArgs = ['-Xms512m', '-Xmx4g']
        }
    }
}

publishing {

    repositories {
        maven {
            name = "MauroSnapshot"
            url = "https://mauro-repository.com/libs-snapshot-local"
            credentials(PasswordCredentials)
            authentication {
                basic(BasicAuthentication)
            }
        }
    }

    publications {
/*        mavenJava(MavenPublication) {
            groupId = 'org.maurodata'
            artifactId = 'dita-dsl'
            version = "2.0.0-SNAPSHOT"
            from components.java
        }
*/        // new lite publication (dita-dsl-base)
        base(MavenPublication) {
            groupId = 'org.maurodata'
            artifactId = 'dita-dsl-base'
            version = "2.0.0-SNAPSHOT"
            artifact(tasks.named("baseJar"))
        }
    }
}

mavenPublishing {
    configure(new JavaLibrary(new JavadocJar.None(), true))
    publishToMavenCentral(SonatypeHost.CENTRAL_PORTAL, true)
    signAllPublications()
    //coordinates(group, rootProject.name, version)

    pom {
        name = 'DITA Groovy DSL'
        description = 'Provides a MarkupBuilder for editing DITA XML from Groovy code'
        url = "https://github.com/MauroDataMapper/dita-groovy-dsl"
        licenses {
            license {
                name = 'The Apache License, Version 2.0'
                url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
            }
        }
        developers {
            developer {
                id = 'jamesrwelch'
                name = 'James Welch'
                email = 'james.welch@bdi.ox.ac.uk'
            }
        }
        scm {
            url = "https://github.com/MauroDataMapper/dita-groovy-dsl"
        }

    }
}

tasks.withType(PublishToMavenRepository).configureEach {
    mustRunAfter(tasks.withType(Sign)) // ensures signing is finished first
}
tasks.withType(PublishToMavenLocal).configureEach {
    mustRunAfter(tasks.withType(Sign)) // ensures signing is finished first
}
apply from: 'dependencies.gradle'