fgms/build_docs.bat at master · FlightGear/fgms · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
@setlocal
@if NOT EXIST version goto NOFILE
@doxygen --help >nul 2>&1
@if ERRORLEVEL 2 goto NODOXY
@set TMPFIL=docs\doxy.conf
@if NOT EXIST %TMPFIL% goto NOCONF

@set VER=
@set /P VER= < version

@if "%VER%x" == "x" goto FAILED

@echo Setting version VER=%VER%
@copy %TMPFIL% temp.conf >nul
@if NOT EXIST temp.conf goto NOCOPY

@echo PROJECT_NUMBER=%VER% >>temp.conf

doxygen temp.conf
@del temp.conf >nul
@echo Looks to be a successful generation...

@goto END

:NOCOPY
@echo ERROR: Unable to copy %TMPFIL% to temp.conf!
@goto ISERR

:NOFILE
@echo ERROR: Can NOT locate 'version' file!
@goto ISERR

:NOCONF
@echo ERROR: Unable to locate file %TMPFIL%!
@echo Where is the doxygen config file?
@goto ISERR

:NODOXY
@echo ERROR: Unable to run doxygen app! Is it installed in the PATH?
@goto ISERR

:FAILED
@echo Failed to SET VER=%VER%
@goto ISERR

:ISERR
@endlocal
@exit /b 1


:END
@endlocal
@exit /b 0

@REM eof